File Coverage

blib/lib/HealthCheck/Diagnostic/SSH.pm

Criterion	Covered	Total	%
statement	59	60	98.3
branch	18	22	81.8
condition	4	7	57.1
subroutine	10	10	100.0
pod	5	5	100.0
total	96	104	92.3

package HealthCheck::Diagnostic::SSH;

use strict;
use warnings;

use parent 'HealthCheck::Diagnostic';

use Net::SSH::Perl ();

# ABSTRACT: Verify SSH connectivity to specified host.
use version;
our $VERSION = 'v0.1.0'; # VERSION

sub new {
    my ($class, @params) = @_;

    my %params = @params == 1 && ( ref $params[0] || '' ) eq 'HASH'
        ? %{ $params[0] } : @params;

    return $class->SUPER::new(
        id     => 'ssh',
        label  => 'SSH',
        %params,
    );
}

sub check {
    my ($self, %params) = @_;

    # Make it so that the diagnostic can be used as an instance or a
    # class, and the `check` params get preference.
    if ( ref $self ) {
        $params{ $_ } = $self->{ $_ }
            foreach grep { ! defined $params{ $_ } } keys %$self;
    }

    # The host is the only required parameter.
    return {
        id     => $params{'id'},
        label  => $params{'label'},
        status => 'UNKNOWN',
        info   => "Missing required input: No host specified",
    } unless $params{host};

    return $self->SUPER::check(%params);
}

sub run {
    my ($self, %params) = @_;

    # Get our description of the connection.
    my $user          = $params{user};
    my $name          = $params{name};
    my $target        = ( $user ? $user.'@' : '' ).$params{host};
    my $description   = $name ? "$name ($target) SSH" : "$target SSH";

    # connect to SSH
    my $ssh;
    local $@;
    eval {
        local $SIG{__DIE__};
        $ssh = $self->ssh_connect( %params );
    };
    return {
        status => 'CRITICAL',
        info   => "Error for $description: $@",
    } if $@;

    # if there were no errors, it should've connected
    return {
        status => 'OK',
        info   => "Successful connection for $description",
    } unless $params{command};

    # run command if exists
    my %res = $self->run_command( $ssh, %params );
    return {
        status => 'CRITICAL',
        info   => "$description: $res{error}",
    } if $res{error};

    return {
        status => $res{exit_code} == 0 ? 'OK' : 'CRITICAL',
        info   => "$description <$params{command}> exit is $res{exit_code}",
        $params{return_output} ? ( data => \%res ) : (),
    };
}

sub ssh_connect {
    my ( $self, %params ) = @_;

    my $host       = $params{host};
    my $user       = $params{user};
    my $password   = $params{password};
    my %ssh_params = (
        protocol => 2,
        %{ $params{ssh_args} // {} },
    );

    my $ssh = Net::SSH::Perl->new( $host, %ssh_params );
    $ssh->login( $user, $password );

    return $ssh;
}

sub run_command {
    my ( $self, $ssh, %params ) = @_;
    my %res;

    local $@;
    eval {
        local $SIG{__DIE__};
        my ($stdout, $stderr, $exit_code) = $ssh->cmd(
            $params{command},
            $params{stdin} // '',
        );
        $res{ stdout }    = $stdout;
        $res{ stderr }    = $stderr;
        $res{ exit_code } = $exit_code;
    };
    $res{ error } = $@ if $@;

    return %res;
}

1;

__END__