File Coverage

blib/lib/HealthCheck/Diagnostic/DBHPing.pm

Criterion	Covered	Total	%
statement	40	41	97.5
branch	13	14	92.8
condition	6	9	66.6
subroutine	9	9	100.0
pod	3	3	100.0
total	71	76	93.4

package HealthCheck::Diagnostic::DBHPing;

# ABSTRACT: Ping a database handle to check its health
use version;
our $VERSION = 'v1.2.5'; # VERSION

use 5.010;
use strict;
use warnings;
use parent 'HealthCheck::Diagnostic';

use Carp;

sub new {
    my ($class, @params) = @_;

    # Allow either a hashref or even-sized list of params
    my %params = @params == 1 && ( ref $params[0] || '' ) eq 'HASH'
        ? %{ $params[0] } : @params;

    return $class->SUPER::new(
        label => 'dbh_ping',
        %params
    );
}

sub check {
    my ( $self, %params ) = @_;

    my $dbh = $params{dbh};
    $dbh ||= $self->{dbh} if ref $self;
    $dbh = $dbh->(%params) if ref $dbh eq 'CODE';

    croak("Valid 'dbh' is required") unless $dbh and do {
        local $@; local $SIG{__DIE__}; eval { $dbh->can('ping') } };

    my $res = $self->SUPER::check( %params, dbh => $dbh );
    delete $res->{dbh};    # don't include the object in the result

    return $res;
}

sub run {
    my ( $self, %params ) = @_;
    my $dbh = $params{dbh};

    my $status     = $dbh->ping      ? "OK"         : "CRITICAL";
    my $successful = $status eq "OK" ? "Successful" : "Unsuccessful";

    my $driver = $dbh->{Driver}->{Name};
    my $info   = "$successful $driver ping of $dbh->{Name}";
    $info .= " as $dbh->{Username}" if $dbh->{Username};

    return { status => $status, info => $info };
}

1;

__END__