File Coverage

blib/lib/HashDataRole/Source/Iterator.pm

Criterion	Covered	Total	%
statement	56	59	94.9
branch	21	26	80.7
condition	1	2	50.0
subroutine	11	12	91.6
pod	0	7	0.0
total	89	106	83.9

package HashDataRole::Source::Iterator;

use strict;
use 5.010001;
use Role::Tiny;
use Role::Tiny::With;
with 'HashDataRole::Spec::Basic';

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-11-04'; # DATE
our $DIST = 'HashDataRoles-Standard'; # DIST
our $VERSION = '0.005'; # VERSION

sub _new {
    my ($class, %args) = @_;

    my $gen_iterator = delete $args{gen_iterator} or die "Please specify 'gen_iterator' argument";
    my $gen_iterator_params = delete $args{gen_iterator_params} // {};

    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    bless {
        gen_iterator => $gen_iterator,
        gen_iterator_params => $gen_iterator_params,
        iterator => undef,
        pos => 0,
        # buf => '', # exists when there is a buffer
    }, $class;
}

sub get_next_item {
    my $self = shift;
    $self->reset_iterator unless $self->{iterator};
    if (exists $self->{buf}) {
        $self->{pos}++;
        return delete $self->{buf};
    } else {
        my ($key, $val) = $self->{iterator}->();
        die "StopIteration" unless defined $key;
        $self->{pos}++;
        return [$key, $val];
    }
}

sub has_next_item {
    my $self = shift;
    if (exists $self->{buf}) {
        return 1;
    }
    $self->reset_iterator unless $self->{iterator};
    my ($key,$val) = $self->{iterator}->();
    return 0 unless defined $key;
    $self->{buf} = [$key,$val];
    1;
}

sub reset_iterator {
    my $self = shift;
    $self->{iterator} = $self->{gen_iterator}->(%{ $self->{gen_iterator_params} });
    $self->{pos} = 0;
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub get_item_at_key {
    my ($self, $key) = @_;
    $self->reset_iterator;
    while (1) {
        return unless $self->has_next_item;
        my $item = $self->get_next_item;
        return $item if $item->[0] eq $key;
    }
}

sub has_item_at_key {
    my ($self, $key) = @_;
    $self->reset_iterator;
    while (1) {
        return 0 unless $self->has_next_item;
        my $item = $self->get_next_item;
        return 1 if $item->[0] eq $key;
    }
}

sub get_all_keys {
    my ($self) = @_;
    $self->reset_iterator;
    my @keys;
    while (1) {
        last unless $self->has_next_item;
        my $item = $self->get_next_item;
        push @keys, $item->[0];
    }
    @keys;
}

1;
# ABSTRACT: Get hash data from an iterator

__END__