File Coverage

blib/lib/HashDataRole/Source/Array.pm

Criterion	Covered	Total	%
statement	42	51	82.3
branch	13	22	59.0
condition			n/a
subroutine	12	14	85.7
pod	0	11	0.0
total	67	98	68.3

package HashDataRole::Source::Array;

use 5.010001;
use Role::Tiny;
use Role::Tiny::With;

with 'HashDataRole::Spec::Basic';
with 'Role::TinyCommons::Collection::GetItemByPos'; # bonus

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-11-04'; # DATE
our $DIST = 'HashDataRoles-Standard'; # DIST
our $VERSION = '0.005'; # VERSION

sub new {
    my ($class, %args) = @_;

    my $ary = delete $args{array} or die "Please specify 'array' argument";

    die "Unknown argument(s): ". join(", ", sort keys %args)
        if keys %args;

    # create a hash from an array for quick lookup by key. we also check for
    # duplicates here.
    my $hash = {};
    for my $elem (@$ary) {
        die "Duplicate key '$elem->[0]'" if exists $hash->{$elem->[0]};
        $hash->{$elem->[0]} = $elem;
    }

    bless {
        array => $ary,
        _hash => $hash,
        pos => 0,
    }, $class;
}

sub get_next_item {
    my $self = shift;
    die "StopIteration" unless $self->{pos} < @{ $self->{array} };
    $self->{array}->[ $self->{pos}++ ];
}

sub has_next_item {
    my $self = shift;
    $self->{pos} < @{ $self->{array} };
}

sub reset_iterator {
    my $self = shift;
    $self->{pos} = 0;
}

sub get_iterator_pos {
    my $self = shift;
    $self->{pos};
}

sub get_item_count {
    my $self = shift;
    scalar @{ $self->{array} };
}

sub get_item_at_pos {
    my ($self, $pos) = @_;
    if ($pos < 0) {
        die "Out of range" unless -$pos <= @{ $self->{array} };
    } else {
        die "Out of range" unless $pos < @{ $self->{array} };
    }
    $self->{array}->[ $pos ];
}

sub has_item_at_pos {
    my ($self, $pos) = @_;
    if ($pos < 0) {
        return -$pos <= @{ $self->{array} } ? 1:0;
    } else {
        return $pos < @{ $self->{array} } ? 1:0;
    }
}

sub get_item_at_key {
    my ($self, $key) = @_;
    die "No such key '$key'" unless exists $self->{_hash}{$key};
    $self->{_hash}{$key}[1];
}

sub has_item_at_key {
    my ($self, $key) = @_;
    exists $self->{_hash}{$key};
}

sub get_all_keys {
    my ($self, $key) = @_;
    # to be more deterministic
    sort keys %{$self->{_hash}};
}

1;
# ABSTRACT: Get hash data from a Perl array

__END__