File Coverage

lib/Gtk2/Ex/MindMapView/ContentFactory.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Gtk2::Ex::MindMapView::ContentFactory;

our $VERSION = '0.000001';

use warnings;
use strict;
use Carp;

use Gtk2::Ex::MindMapView::Content::EllipsisText;
use Gtk2::Ex::MindMapView::Content::Picture;
use Gtk2::Ex::MindMapView::Content::Uri;

use Gtk2::Ex::MindMapView::ArgUtils;

use List::Util;

use Glib ':constants';

sub new
{
    my $class = shift(@_);

    my @attributes = @_;

    my $self = {};

    bless $self, $class;

    my %attributes = @attributes;

    args_valid(\%attributes, qw(view font_desc text_color_gdk));

    args_required(\%attributes, qw(view));

    args_store($self, \%attributes);

    if (!($self->{view}->isa('Gtk2::Ex::MindMapView')))
    {
	carp "Invalid Gtk2::Ex::MindMapView argument.\n";
    }

    arg_default($self, "font_desc", Gtk2::Pango::FontDescription->from_string("Ariel Normal 10"));

    arg_default($self, "text_color_gdk", Gtk2::Gdk::Color->parse('black'));

    return $self;
}


sub create_content
{
    my ($self, @attributes) = @_;

    my %attributes = @attributes;

    args_valid(\%attributes, qw(type text uri pixbuf browser font_desc text_color_gdk));

    args_required(\%attributes, qw(type));

    my $type           = $attributes{type};

    my $text           = $attributes{text};

    my $uri            = $attributes{uri};

    my $browser        = $attributes{browser};

    my $pixbuf         = $attributes{pixbuf};

    my $font_desc      = (defined $attributes{font_desc}) ?
	                     $attributes{font_desc} : $self->{font_desc};

    my $text_color_gdk = (defined $attributes{text_color_gdk}) ?
	                     $attributes{text_color_gdk} : $self->{text_color_gdk};

    if ($type eq 'Gtk2::Ex::MindMapView::Content::EllipsisText')
    {
	return Gtk2::Ex::MindMapView::Content::EllipsisText->new(
		       group=>$self->{view}->root,
		       text=>$text,
		       font_desc=>$font_desc,
		       text_color_gdk=>$text_color_gdk);
    }

    if ($type eq 'Gtk2::Ex::MindMapView::Content::Picture')
    {
	return Gtk2::Ex::MindMapView::Content::Picture->new(
		       group=>$self->{view}->root,
		       pixbuf=>$pixbuf);
    }


    if ($type eq 'Gtk2::Ex::MindMapView::Content::Uri')
    {
	return Gtk2::Ex::MindMapView::Content::Uri->new(
		       group=>$self->{view}->root,
		       browser=>$browser,
		       text=>$text, uri=>$uri,
		       font_desc=>$font_desc,
		       text_color_gdk=>$text_color_gdk);
    }

    croak "Unexpected content type: $type\n";
}


1; # Magic true value required at end of module
__END__