File Coverage

blib/lib/Gnuplot/Builder/PartiallyKeyedList.pm

Criterion	Covered	Total	%
statement	70	70	100.0
branch	17	24	70.8
condition	3	9	33.3
subroutine	16	16	100.0
pod	12	12	100.0
total	118	131	90.0

package Gnuplot::Builder::PartiallyKeyedList;
use strict;
use warnings;
use Carp;

sub new {
    my ($class) = @_;
    my $self = bless {
        index_for => {},
        keys => [],
        values => [],
    }, $class;
    return $self;
}

sub set {
    my ($self, $key, $value) = @_;
    croak "key must be defined" if not defined $key;
    my $index = $self->{index_for}{$key};
    if(defined($index)) {
        $self->{values}[$index] = $value;
    }else {
        push(@{$self->{keys}}, $key);
        push(@{$self->{values}}, $value);
        $self->{index_for}{$key} = $#{$self->{keys}};
    }
}

sub get {
    my ($self, $key) = @_;
    croak "key must be defined" if not defined $key;
    my $index = $self->{index_for}{$key};
    return defined($index) ? $self->{values}[$index] : undef;
}

sub get_at {
    my ($self, $index) = @_;
    croak "index out of bounds" if $index < 0 || $index >= $self->size;
    return ($self->{keys}[$index], $self->{values}[$index]);
}

sub get_all_keys {
    my ($self) = @_;
    return @{$self->{keys}};
}

sub get_all_values {
    my ($self) = @_;
    return @{$self->{values}};
}

sub exists {
    my ($self, $key) = @_;
    croak "key must be defined" if not defined $key;
    return defined($self->{index_for}{$key});
}

sub delete {
    my ($self, $key) = @_;
    croak "key must be defined" if not defined $key;
    my $index = delete $self->{index_for}{$key};
    return undef if not defined $index;
    splice(@{$self->{keys}}, $index, 1);
    my $value = splice(@{$self->{values}}, $index, 1);

    foreach my $existing_index (values %{$self->{index_for}}) {
        $existing_index-- if $existing_index > $index;
    }
    return $value;
}

sub add {
    my ($self, $entry) = @_;
    push(@{$self->{keys}}, undef);
    push(@{$self->{values}}, $entry);
}

sub each {
    my ($self, $code) = @_;
    croak "code must be a code-ref" if !defined($code) || ref($code) ne "CODE";
    foreach my $index (0 .. $#{$self->{keys}}) {
        $code->($self->{keys}[$index], $self->{values}[$index]);
    }
}

sub merge {
    my ($self, $another) = @_;
    croak "another_pkl must be an object" if !defined($another) || !ref($another);
    $another->each(sub {
        my ($key, $value) = @_;
        if(defined($key)) {
            $self->set($key, $value);
        }else {
            $self->add($value);
        }
    });
}

sub size { scalar(@{ $_[0]->{keys} }) }

1;

__END__