File Coverage

lib/Git/Lint/Config.pm

Criterion	Covered	Total	%
statement	60	64	93.7
branch	14	18	77.7
condition	6	9	66.6
subroutine	10	10	100.0
pod	2	2	100.0
total	92	103	89.3

package Git::Lint::Config;

use strict;
use warnings;

use Module::Loader;
use List::MoreUtils ();
use Git::Lint::Command;

our $VERSION = '1.000';

sub load {
    my $class = shift;
    my $self  = { profiles => undef };

    $self->{profiles}{commit}{default}  = [];
    $self->{profiles}{message}{default} = [];

    bless $self, $class;

    my $user_config = $self->user_config();

    # add user defined config settings
    if ( exists $user_config->{config} ) {
        $self->{config} = $user_config->{config};
    }

    # if localdir is defined, add it into INC to load modules from
    if ( exists $self->{config} && defined $self->{config}{localdir} ) {
        if ( -d $self->{config}{localdir} ) {
            push @INC, $self->{config}{localdir};
        }
        else {
            warn "git-lint: [warn] configured localdir $self->{config}{localdir} isn't a readable directory\n";
        }
    }

    # all check modules are added to the default profile
    my $loader        = Module::Loader->new;
    my $namespace     = 'Git::Lint::Check::Commit';
    my @commit_checks = List::MoreUtils::apply {s/$namespace\:\://g} $loader->find_modules( $namespace, { max_depth => 1 } );

    if (@commit_checks) {
        $self->{profiles}{commit}{default} = \@commit_checks;
    }

    $namespace = 'Git::Lint::Check::Message';
    my @message_checks = List::MoreUtils::apply {s/$namespace\:\://g} $loader->find_modules( $namespace, { max_depth => 1 } );

    if (@message_checks) {
        $self->{profiles}{message}{default} = \@message_checks;
    }

    # user defined profiles override internally defined profiles
    foreach my $check ( keys %{ $user_config->{profiles} } ) {
        foreach my $profile ( keys %{ $user_config->{profiles}{$check} } ) {
            $self->{profiles}{$check}{$profile} = $user_config->{profiles}{$check}{$profile};
        }
    }

    return $self;
}

sub user_config {
    my $self = shift;

    my @git_config_cmd = (qw{ git config --get-regexp ^lint });

    my ( $stdout, $stderr, $exit ) = Git::Lint::Command::run( \@git_config_cmd );

    # if there is no user config, the git config command above will return 1
    # but without stderr.
    if ( $exit && !$stderr ) {
        die "configuration setup is required. see the documentation for instructions.\n";
    }

    # if there was an error, propagate that up.
    if ( $exit && $stderr ) {
        die "$stderr\n";
    }

    my %parsed_config = ();

    # load check profiles
    foreach my $line ( split( /\n/, $stdout ) ) {
        next unless $line =~ /^lint\.profiles\.(\w+)\.(\w+)\s+(.+)$/;
        my ( $check, $profile, $value ) = ( $1, $2, $3 );

        my @values = List::MoreUtils::apply {s/^\s+|\s+$//g} split( /,/, $value );
        push @{ $parsed_config{profiles}{$check}{$profile} }, @values;
    }

    # load other config settings
    foreach my $line ( split( /\n/, $stdout ) ) {
        if ( $line =~ /^lint\.config\.localdir\s+(.+)$/ ) {
            my ($value) = ($1);
            $parsed_config{config}{localdir} = $value;
        }
    }

    return \%parsed_config;
}

1;

__END__