File Coverage

blib/lib/Geo/Location/IP/Network.pm

Criterion	Covered	Total	%
statement	37	39	94.8
branch	5	6	83.3
condition			n/a
subroutine	12	13	92.3
pod	4	6	66.6
total	58	64	90.6

package Geo::Location::IP::Network;

# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later

use 5.026;
use warnings;
use utf8;

use Object::Pad;

class Geo::Location::IP::Network;

our $VERSION = 0.005;

use Scalar::Util qw();
use Socket       qw();

field $network_address :reader;
field $prefixlen :param :reader;
field $version :reader;

method with_prefixlen () {
    if (defined $network_address) {
        return $network_address . '/' . $prefixlen;
    }
    return;
}

#<<<
ADJUST :params (:$address) {
    if (defined $address && defined $prefixlen && $prefixlen >= 0) {
        if ($prefixlen <= 32 && index($address, '.') >= 0) {
            my $family         = Socket::AF_INET;
            my $packed_address = Socket::inet_pton($family, $address);
            if (defined $packed_address) {
                my $packed_mask = ~pack 'N', (1 << (32 - $prefixlen)) - 1;
                $network_address = Socket::inet_ntop($family,
                    $packed_address & $packed_mask);
                $version = 4;
            }
        }
        elsif ($prefixlen <= 128 && index($address, ':') >= 0) {
            my $family         = Socket::AF_INET6;
            my $packed_address = Socket::inet_pton($family, $address);
            if (defined $packed_address) {
                my $bits        = '1' x $prefixlen . '0' x (128 - $prefixlen);
                my $packed_mask = pack 'B128', $bits;
                $network_address = Socket::inet_ntop($family,
                    $packed_address & $packed_mask);
                $version = 6;
            }
        }
    }
}
#>>>

use overload
    q{eq} => \&eq,
    q{""} => \&stringify;

sub eq {
    my ($self, $other) = @_;

    if (Scalar::Util::blessed($other)) {
        if ($other->isa(__PACKAGE__)) {
            return $self->with_prefixlen eq $other->with_prefixlen;
        }
    }
    return $self->with_prefixlen eq $other;
}

sub stringify {
    my $self = shift;

    return $self->with_prefixlen;
}

1;
__END__