File Coverage

blib/lib/Geo/Location/IP/Model/City.pm

Criterion	Covered	Total	%
statement	87	87	100.0
branch	2	2	100.0
condition	13	20	65.0
subroutine	25	25	100.0
pod	11	11	100.0
total	138	145	95.1

package Geo::Location::IP::Model::City;

# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later

use 5.026;
use warnings;
use utf8;

use Object::Pad;

class Geo::Location::IP::Model::City;

our $VERSION = 0.005;

use Geo::Location::IP::Record::City;
use Geo::Location::IP::Record::Continent;
use Geo::Location::IP::Record::Country;
use Geo::Location::IP::Record::Location;
use Geo::Location::IP::Record::MaxMind;
use Geo::Location::IP::Record::Postal;
use Geo::Location::IP::Record::RepresentedCountry;
use Geo::Location::IP::Record::Subdivision;
use Geo::Location::IP::Record::Traits;

field $city :param :reader;
field $continent :param :reader;
field $country :param :reader;
field $location :param :reader;
field $maxmind :param :reader;
field $postal :param :reader;
field $registered_country :param :reader;
field $represented_country :param :reader;
field $subdivisions :param;
field $traits :param :reader;

method most_specific_subdivision () {
    if (@{$subdivisions} > 0) {
        return $subdivisions->[-1];
    }
    return Geo::Location::IP::Record::Subdivision->new(
        names   => {},
        locales => [],
    );
}

method subdivisions () {
    return @{$subdivisions};
}

sub _from_hash ($class, $hash_ref, $ip_address, $locales) {
    my $city
        = Geo::Location::IP::Record::City->_from_hash($hash_ref->{city} // {},
        $locales);

    my $continent = Geo::Location::IP::Record::Continent->_from_hash(
        $hash_ref->{continent} // {}, $locales);

    my $country
        = Geo::Location::IP::Record::Country->_from_hash($hash_ref->{country}
            // {}, $locales);

    my $location = Geo::Location::IP::Record::Location->_from_hash(
        $hash_ref->{location} // {});

    my $maxmind
        = Geo::Location::IP::Record::MaxMind->_from_hash($hash_ref->{maxmind}
            // {});

    my $postal
        = Geo::Location::IP::Record::Postal->_from_hash($hash_ref->{postal}
            // {});

    my $registered_country = Geo::Location::IP::Record::Country->_from_hash(
        $hash_ref->{registered_country} // {}, $locales);

    my $represented_country
        = Geo::Location::IP::Record::RepresentedCountry->_from_hash(
        $hash_ref->{represented_country} // {}, $locales);

    my @subdivisions = map {
        Geo::Location::IP::Record::Subdivision->_from_hash($_, $locales)
    } @{$hash_ref->{subdivisions} // []};

    my $traits
        = Geo::Location::IP::Record::Traits->_from_hash($hash_ref->{traits}
            // {}, $ip_address);

    return $class->new(
        city                => $city,
        continent           => $continent,
        country             => $country,
        location            => $location,
        maxmind             => $maxmind,
        postal              => $postal,
        registered_country  => $registered_country,
        represented_country => $represented_country,
        subdivisions        => \@subdivisions,
        traits              => $traits,
    );
}

1;
__END__