File Coverage

blib/lib/Geo/Location/IP/Address.pm

Criterion	Covered	Total	%
statement	41	43	95.3
branch	6	8	75.0
condition	2	3	66.6
subroutine	12	13	92.3
pod	3	5	60.0
total	64	72	88.8

package Geo::Location::IP::Address;

# SPDX-License-Identifier: Artistic-1.0-Perl OR GPL-1.0-or-later

use 5.026;
use warnings;
use utf8;

use Object::Pad;

class Geo::Location::IP::Address;

our $VERSION = 0.005;

use Geo::Location::IP::Network;
use Scalar::Util qw();

field $address :param :reader;
field $network :param :reader;
field $version :reader;

ADJUST {
    if (defined $address) {
        if (defined $network && defined $network->version) {
            $version = $network->version;
        }
        else {
            if (index($address, '.') >= 0) {
                $version = 4;
                if (!defined $network) {
                    $network = Geo::Location::IP::Network->new(
                        address   => $address,
                        prefixlen => 32
                    );
                }
            }
            elsif (index($address, ':') >= 0) {
                $version = 6;
                if (!defined $network) {
                    $network = Geo::Location::IP::Network->new(
                        address   => $address,
                        prefixlen => 128
                    );
                }
            }
        }
    }
}

sub _from_hash ($class, $hash_ref, $ip_address) {
    # If a web service accepts "me" as an IP address, the returned IP address
    # may differ from the local host's IP address if the host is behind a NAT
    # gateway.
    if (exists $hash_ref->{ip_address}) {
        my $ip = $hash_ref->{ip_address};
        if (!defined $ip_address || $ip_address->address ne $ip) {
            $ip_address = $class->new(address => $ip, network => undef);
        }
    }
    return $ip_address;
}

use overload
    q{eq} => \&eq,
    q{""} => \&stringify;

sub eq {
    my ($self, $other) = @_;

    if (Scalar::Util::blessed($other)) {
        if ($other->isa(__PACKAGE__)) {
            return $self->address eq $other->address;
        }
    }
    return $self->address eq $other;
}

sub stringify {
    my $self = shift;

    return $self->address;
}

1;
__END__