File Coverage

blib/lib/Gears/Template.pm

Criterion	Covered	Total	%
statement	42	49	85.7
branch	9	10	90.0
condition	2	3	66.6
subroutine	7	8	87.5
pod	1	1	100.0
total	61	71	85.9

package Gears::Template;
$Gears::Template::VERSION = '0.101';
use v5.40;
use Mooish::Base -standard;

use Path::Tiny qw(path);
use Gears::X::Template;

has param 'encoding' => (
	isa => Str,
	default => 'UTF-8',
);

has param 'paths' => (
	isa => ArrayRef [Str],
	default => sub { [] },
);

# implements actual rendering of a template
# must be reimplemented
sub _render_template ($self, $template_content, $vars)
{
	...;
}

sub process ($self, $template, $vars = {})
{
	my $ref = ref $template;

	# A GLOB or an IO object will be read and returned as a SCALAR template
	# No reference means a file name
	if (!$ref) {
		$template = $self->_read_file($self->_find_template($template));
	}
	elsif ($ref eq 'GLOB' || $template isa 'IO::Handle') {
		$template = $self->_read_file($template);
	}
	elsif ($ref eq 'SCALAR') {
		$template = $template->$*;
	}
	else {
		Gears::X::Template->raise("Template must be either a SCALAR or GLOB reference, or an IO::Handle object");
	}

	return $self->_render_template($template, $vars);
}

sub _find_template ($self, $name)
{
	for my $p ($self->paths->@*) {
		my $file = "$p/$name";
		return $file if -f $file;
	}

	Gears::X::Template->raise("Template file not found: $name");
}

sub _read_file ($self, $file)
{
	my $text;

	if (ref $file) {
		# read the entire file
		local $/ = undef;

		# make sure to properly rewind the handle after we read from it
		my $pos = tell $file;
		$text = readline $file;
		seek $file, $pos, 0;
	}
	else {
		$text = path($file)->slurp(
			{binmode => ':encoding(' . $self->encoding . ')'}
		);
	}

	return $text;
}

__END__