File Coverage

blib/lib/Gears/Router.pm

Criterion	Covered	Total	%
statement	58	63	92.0
branch	6	6	100.0
condition			n/a
subroutine	11	12	91.6
pod	5	5	100.0
total	80	86	93.0

package Gears::Router;
$Gears::Router::VERSION = '0.101';
use v5.40;
use Mooish::Base -standard;

use Gears::Router::Match;

with qw(Gears::Router::Proto);

# we are the router
has extended 'router' => (
	init_arg => undef,
	default => sub ($self) { $self },
);

# base route is an empty string
sub pattern ($self)
{
	return '';
}

# builds a new location - see Gears::Router::Proto
# - must create a new subclass of Gears::Router::Location, where %args are
#   constructor arguments
# - must be reimplemented
sub _build_location ($self, %args)
{
	...;
}

# builds a new match
# can be reimplemented
sub _build_match ($self, %args)
{
	return Gears::Router::Match->new(%args);
}

sub _match_level ($self, $locations, @args)
{
	my @matched;
	foreach my $loc ($locations->@*) {
		next unless my $match_data = $loc->compare(@args);
		my $match = $self->_build_match(
			location => $loc,
			matched => $match_data,
		);

		my $children = $loc->locations;
		if ($children->@* > 0) {
			push @matched, [$match, $self->_match_level($children, @args)];
		}
		else {
			push @matched, $match;
		}
	}

	return @matched;
}

sub _match ($self, @args)
{
	return [$self->_match_level($self->locations, @args)];
}

sub match
{
	goto \&_match;
}

sub flat_match ($self, @args)
{
	my $matches = $self->_match(@args);
	return $self->flatten($matches);
}

sub flatten ($self, $matches)
{
	my @flat_matches;
	foreach my $match ($matches->@*) {
		if (ref $match eq 'ARRAY') {
			push @flat_matches, $self->flatten($match);
		}
		else {
			push @flat_matches, $match;
		}
	}

	return @flat_matches;
}

sub clear ($self)
{
	$self->locations->@* = ();
	return $self;
}

__END__