File Coverage

blib/lib/Games/Solitaire/Verify/KlondikeTalon.pm

Criterion	Covered	Total	%
statement	15	61	24.5
branch	0	12	0.0
condition			n/a
subroutine	5	11	45.4
pod	4	4	100.0
total	24	88	27.2

package Games::Solitaire::Verify::KlondikeTalon;
$Games::Solitaire::Verify::KlondikeTalon::VERSION = '0.2601';
use warnings;
use strict;


use parent 'Games::Solitaire::Verify::Base';

use Games::Solitaire::Verify::Exception ();
use Games::Solitaire::Verify::Card      ();

__PACKAGE__->mk_acc_ref(
    [
        qw(
            _max_num_redeals
            _num_redeals_so_far
            _undealt_cards
            _waste
        )
    ]
);


sub _input_from_string
{
    my $self = shift;
    my $str  = shift;

    if ( my ($cards_str) = ( $str =~ /\ATalon: (.*)\z/ms ) )
    {
        $self->_undealt_cards(
            [
                map { Games::Solitaire::Verify::Card->new( { string => $_, } ) }
                    split /\s+/,
                $cards_str
            ]
        );
    }
    else
    {
        die "Wrong format - does not start with Talon.";
    }
}

sub _init
{
    my ( $self, $args ) = @_;

    $self->_max_num_redeals( $args->{max_num_redeals} );

    $self->_num_redeals_so_far(0);

    $self->_undealt_cards( [] );
    $self->_waste( [] );

    if ( exists( $args->{string} ) )
    {
        $self->_input_from_string( $args->{string} );
    }

    return;
}


sub draw
{
    my $self = shift;

    if ( !@{ $self->_undealt_cards() } )
    {
        die "Cannot draw.";
    }

    push @{ $self->_waste() }, shift( @{ $self->_undealt_cards() } );

    return;
}


sub extract_top
{
    my $self = shift;

    if ( !@{ $self->_waste() } )
    {
        die "Cannot extract_top.";
    }

    return pop( @{ $self->_waste() } );
}


sub redeal
{
    my $self = shift;

    if ( @{ $self->_undealt_cards() } )
    {
        die "Cannot redeal while there are remaining cards.";
    }

    if ( $self->_num_redeals_so_far() == $self->_max_num_redeals() )
    {
        die "Cannot redeal because maximal number exceeded.";
    }

    $self->_num_redeals_so_far( $self->_num_redeals_so_far() + 1 );

    push @{ $self->_undealt_cards() }, @{ $self->_waste() };

    $self->_waste( [] );

    return;
}


sub to_string
{
    my $self = shift;

    return join( " ",
        "Talon:", ( map { $_->fast_s() } reverse @{ $self->_waste() } ),
        '==>', ( map { $_->fast_s() } @{ $self->_undealt_cards() } ), '<==', );
}

1;    # End of Games::Solitaire::Verify::KlondikeTalon

__END__