| 1 | package Game::Durak::Bout; | ||
| 2 | |||
| 3 | use strict; | ||
| 4 | use warnings; | ||
| 5 | |||
| 6 | use Object::Proto::Sugar -types; | ||
| 7 | |||
| 8 | use Game::Durak::Card (); | ||
| 9 | |||
| 10 | our $VERSION = '0.04'; | ||
| 11 | |||
| 12 | has attacker => (is => 'ro', isa => Int); | ||
| 13 | has defender => (is => 'ro', isa => Int); | ||
| 14 | has cap => (is => 'ro', isa => Int); | ||
| 15 | |||
| 16 | has attacks => (is => 'rw', isa => ArrayRef, default => sub { [] }); | ||
| 17 | has beats => (is => 'rw', isa => ArrayRef, default => sub { [] }); | ||
| 18 | has taken => (is => 'rw', isa => Int, default => 0); | ||
| 19 | |||
| 20 | sub build { | ||
| 21 | my ($class, %o) = @_; | ||
| 22 | |||
| 23 | my ($attacker, $defender, $cap) = @o{qw(attacker defender cap)}; | ||
| 24 | |||
| 25 | die "Game::Durak::Bout: a bout wants two different seats\n" | ||
| 26 | unless defined $attacker && defined $defender | ||
| 27 | && $attacker =~ /\A[12]\z/ && $defender =~ /\A[12]\z/ | ||
| 28 | && $attacker != $defender; | ||
| 29 | |||
| 30 | die "Game::Durak::Bout: a bout wants a cap of one to six, not " | ||
| 31 | . (defined $cap ? "'$cap'" : 'undef') . "\n" | ||
| 32 | unless defined $cap && $cap =~ /\A[1-6]\z/; | ||
| 33 | |||
| 34 | return $class->new( | ||
| 35 | attacker => $attacker, | ||
| 36 | defender => $defender, | ||
| 37 | cap => $cap, | ||
| 38 | attacks => [], | ||
| 39 | beats => [], | ||
| 40 | taken => 0, | ||
| 41 | ); | ||
| 42 | } | ||
| 43 | |||
| 44 | sub size { return scalar @{ $_[0]->attacks } } | ||
| 45 | |||
| 46 | sub room { my ($self) = @_; return $self->cap - $self->size } | ||
| 47 | |||
| 48 | sub unbeaten { | ||
| 49 | my ($self) = @_; | ||
| 50 | my $attacks = $self->attacks; | ||
| 51 | my $beats = $self->beats; | ||
| 52 | for my $i (0 .. $#$attacks) { | ||
| 53 | return $attacks->[$i] unless defined $beats->[$i]; | ||
| 54 | } | ||
| 55 | return undef; | ||
| 56 | } | ||
| 57 | |||
| 58 | sub all_beaten { return defined $_[0]->unbeaten ? 0 : 1 } | ||
| 59 | |||
| 60 | sub cards { | ||
| 61 | my ($self) = @_; | ||
| 62 | return ( @{ $self->attacks }, grep { defined } @{ $self->beats } ); | ||
| 63 | } | ||
| 64 | |||
| 65 | sub ranks { | ||
| 66 | my ($self) = @_; | ||
| 67 | my %rank; | ||
| 68 | $rank{ Game::Durak::Card::rank_of($_) } = 1 for $self->cards; | ||
| 69 | return \%rank; | ||
| 70 | } | ||
| 71 | |||
| 72 | sub add_attack { | ||
| 73 | my ($self, $card) = @_; | ||
| 74 | die "Game::Durak::Bout: the attack is at its cap\n" if $self->room < 1; | ||
| 75 | $self->attacks([ @{ $self->attacks }, $card ]); | ||
| 76 | $self->beats([ @{ $self->beats }, undef ]); | ||
| 77 | return $self; | ||
| 78 | } | ||
| 79 | |||
| 80 | sub add_beat { | ||
| 81 | my ($self, $card) = @_; | ||
| 82 | my $beats = [ @{ $self->beats } ]; | ||
| 83 | for my $i (0 .. $#$beats) { | ||
| 84 | next if defined $beats->[$i]; | ||
| 85 | $beats->[$i] = $card; | ||
| 86 | $self->beats($beats); | ||
| 87 | return $self; | ||
| 88 | } | ||
| 89 | die "Game::Durak::Bout: nothing is waiting to be beaten\n"; | ||
| 90 | } | ||
| 91 | |||
| 92 | 1; | ||
| 93 | |||
| 94 | __END__ |