File Coverage

blib/lib/Future/IO/Impl/AnyEvent.pm

Criterion	Covered	Total	%
statement	55	74	74.3
branch	5	6	83.3
condition			n/a
subroutine	17	24	70.8
pod	3	5	60.0
total	80	109	73.3

package Future::IO::Impl::AnyEvent;

use strict;
use warnings;
use 5.014;

use base 'Future::IO::ImplBase';

use AnyEvent;
use Future::IO::Impl::AnyEvent::Future;
use IO::Poll qw(POLLIN POLLOUT);

our $VERSION = 0.03;

__PACKAGE__->APPLY;

sub sleep {  ## no critic (ProhibitBuiltinHomonyms)
  my (undef, $sec) = @_;
  my $f = Future::IO::Impl::AnyEvent::Future->new;
  my $w;
  $w = AE::timer $sec, 0, sub { undef $w; $f->done };
  $f->on_cancel(sub { undef $w });
  return $f;
}

# Since version 0.19, Future::IO::ImplBase implements sysread, syswrite, accept,
# connect, etc. on top of a lower-level ->poll method, so we must provide it. We
# still keep ready_for_read and ready_for_write below for compatibility with
# older versions of Future::IO which used those instead.
sub poll {
  my (undef, $fh, $events) = @_;
  my $f = Future::IO::Impl::AnyEvent::Future->new;
  my ($rw, $ww);
  my $done = sub {
    return if $f->is_ready;
    undef $rw;
    undef $ww;
    $f->done($_[0]);
  };
  # AnyEvent only knows about readable (0) and writable (1); there is no way to
  # watch for POLLPRI, but callers always request it together with POLLIN or
  # POLLOUT (e.g. connect polls POLLOUT|POLLPRI), so this is good enough.
  if ($events & POLLIN) {
    $rw = AE::io $fh, 0, sub { $done->(POLLIN) };
  }
  if ($events & POLLOUT) {
    $ww = AE::io $fh, 1, sub { $done->(POLLOUT) };
  }
  $f->on_cancel(sub { undef $rw; undef $ww });
  return $f;
}

sub ready_for_read {
  my (undef, $fh) = @_;
  my $f = Future::IO::Impl::AnyEvent::Future->new;
  my $w;
  $w = AE::io $fh, 0, sub { undef $w; $f->done };
  $f->on_cancel(sub { undef $w });
  return $f;
}

sub ready_for_write {
  my (undef, $fh) = @_;
  my $f = Future::IO::Impl::AnyEvent::Future->new;
  my $w;
  $w = AE::io $fh, 1, sub { undef $w; $f->done };
  $f->on_cancel(sub { undef $w });
  return $f;
}

sub waitpid {  ## no critic (ProhibitBuiltinHomonyms)
  my (undef, $pid) = @_;
  my $f = Future::IO::Impl::AnyEvent::Future->new;
  my $w;
  $w = AE::child $pid, sub { undef $w; $f->done($_[1]) };
  $f->on_cancel(sub { undef $w });
  return $f;
}

1;

__END__