File Coverage

blib/lib/Future/AsyncAwait.pm

Criterion	Covered	Total	%
statement	26	30	86.6
branch	3	6	50.0
condition			n/a
subroutine	10	10	100.0
pod	0	3	0.0
total	39	49	79.5

#  You may distribute under the terms of either the GNU General Public License
#  or the Artistic License (the same terms as Perl itself)
#
#  (C) Paul Evans, 2016-2024 -- [e-mail]

package Future::AsyncAwait 0.71;

use v5.14;
use warnings;

use Carp;

require XSLoader;
XSLoader::load( __PACKAGE__, our $VERSION );

require Future; Future->VERSION( '0.49' );

=head1 NAME

C - deferred subroutine syntax for futures

=head1 SYNOPSIS

=for highlighter language=perl

   use v5.14;
   use Future::AsyncAwait;

   async sub do_a_thing
   {
      my $first = await do_first_thing();

      my $second = await do_second_thing();

      return combine_things( $first, $second );
   }

   do_a_thing()->get;

=head1 DESCRIPTION

This module provides syntax for deferring and resuming subroutines while
waiting for Ls to complete. This syntax aims to make code that
performs asynchronous operations using futures look neater and more expressive
than simply using C chaining and other techniques on the futures
themselves. It is also a similar syntax used by a number of other languages;
notably C# 5, EcmaScript 6, Python 3, Dart, Rust, C++20.

This module is still under active development. While it now seems relatively
stable enough for most use-cases and has received a lot of "battle-testing" in
a wide variety of scenarios, there may still be the occasional case of memory
leak left in it, especially if still-pending futures are abandoned.

The new syntax takes the form of two new keywords, C and C.

=head2 C

The C keyword should appear just before the C keyword that
declares a new function. When present, this marks that the function performs
its work in a I asynchronous fashion. This has two effects: it
permits the body of the function to use the C expression, and it wraps
the return value of the function in a L instance.

   async sub myfunc
   {
      return 123;
   }

   my $f = myfunc();
   my $result = $f->get;

As well as named function declarations it is also supported on anonymous
function expressions.

   my $code = async sub { return 456 };
   my $f = $code->();
   my $result = $f->get;

This C-declared function always returns a C instance when
invoked. The returned future instance will eventually complete when the
function returns, either by the C keyword or by falling off the end;
the result of the future will be the return value from the function's code.
Alternatively, if the function body throws an exception, this will cause the
returned future to fail.

If the final expression in the body of the function returns a C, don't
forget to C it rather than simply returning it as it is, or else this
return value will become double-wrapped - almost certainly not what you
wanted.

   async sub otherfunc { ... }

   async sub myfunc
   {
      ...
      return await otherfunc();
   }

I this module also supports the C keyword on
lexical subroutine declarations when running on Perl version 5.18 or later.
Note that the C keyword has to come first:

   use v5.18;

   my async sub lexfunc { ... }

   my $f = lexfunc(@args);

I this module supports using the C keyword to
declare named subs in other packages.

   async sub Some::Other::Package::myfunc { ... }

=head2 C

The C keyword forms an expression which takes a C instance as
an operand and yields the eventual result of it. Superficially it can be
thought of similar to invoking the C method on the future.

   my $result = await $f;

   my $result = $f->get;

However, the key difference (and indeed the entire reason for being a new
syntax keyword) is the behaviour when the future is still pending and is not
yet complete. Whereas the simple C method would block until the future is
complete, the C keyword causes its entire containing function to become
suspended, making it return a new (pending) future instance. It waits in this
state until the future it was waiting on completes, at which point it wakes up
and resumes execution from the point of the C expression. When the
now-resumed function eventually finishes (either by returning a value or
throwing an exception), this value is set as the result of the future it had
returned earlier.

C provides scalar context to its controlling expression.

   async sub func {
      # this function is invoked in scalar context
   }

   await func();

Because the C keyword may cause its containing function to suspend
early, returning a pending future instance, it is only allowed inside
C-marked subs.

The converse is not true; just because a function is marked as C does
not require it to make use of the C expression. It is still useful to
turn the result of that function into a future, entirely without Cing
on any itself.

Any function that doesn't actually await anything, and just returns immediate
futures can be neatened by this module too.

Instead of writing

   sub imm
   {
      ...
      return Future->done( @result );
   }

you can now simply write

   async sub imm
   {
      ...
      return @result;
   }

with the added side-benefit that any exceptions thrown by the elided code will
be turned into an immediate-failed C rather than making the call
itself propagate the exception, which is usually what you wanted when dealing
with futures.

=head2 await (toplevel)

I

An C expression is also permitted directly in the main script at
toplevel, outside of C. This is implemented by simply invoking the
C method on the future value. Thus, the following two lines are directly
equivalent:

   await afunc();
   afunc()->get;

This is provided as a syntax convenience for unit tests, toplevel scripts, and
so on. It allows code to be written in a style that can be easily moved into
an C, and avoids encouraging "bad habits" of invoking the C
method directly.

=head2 C

I

The C keyword declares a block of code which will be run in the event
that the future returned by the C is cancelled.

   async sub f
   {
      CANCEL { warn "This task was cancelled"; }

      await ...
   }

   f()->cancel;

A C block is a self-contained syntax element, similar to perl
constructions like C, and does not need a terminating semicolon.

When a C block is encountered during execution of the C,
the code in its block is stored for the case that the returned future is
cancelled. Each will take effect as it is executed, possibly multiple times if
it appears inside a loop, or not at all if it appears conditionally in a
branch that was not executed.

   async sub g
   {
      if(0) {
         CANCEL { warn "This does not happen"; }
      }

      foreach my $x ( 1..3 ) {
         CANCEL { warn "This happens for x=$x"; }
      }

      await ...
   }

   g()->cancel;

C blocks are only invoked if a still-pending future is cancelled. They
are discarded without being executed if the function finishes; either
successfully or if it throws an exception.

=head1 Experimental Features

Some of the features of this module are currently marked as experimental. They
will provoke warnings in the C category, unless silenced.

You can silence this with C but then that will
silence every experimental warning, which may hide others unintentionally. For
a more fine-grained approach you can instead use the import line for this
module to only silence this module's warnings selectively:

   use Future::AsyncAwait qw( :experimental(cancel) );

   use Future::AsyncAwait qw( :experimental );  # all of the above

=head1 SUPPORTED USES

Most cases involving awaiting on still-pending futures should work fine:

   async sub foo
   {
      my ( $f ) = @_;

      BEFORE();
      await $f;
      AFTER();
   }

   async sub bar
   {
      my ( $f ) = @_;

      return 1 + await( $f ) + 3;
   }

   async sub splot
   {
      while( COND ) {
         await func();
      }
   }

   async sub wibble
   {
      if( COND ) {
         await func();
      }
   }

   async sub wobble
   {
      foreach my $var ( THINGs ) {
         await func();
      }
   }

   async sub wubble
   {
      # on perl 5.35.5 and above
      foreach my ($k, $v) ( KVTHINGs ) {
         await func();
      }
   }

   async sub quux
   {
      my $x = do {
         await func();
      };
   }

   async sub splat
   {
      eval {
         await func();
      };
   }

Plain lexical variables are preserved across an C deferral:

   async sub quux
   {
      my $message = "Hello, world\n";
      await func();
      print $message;
   }

On perl versions 5.26 and later C syntax supports the C
feature if it is enabled:

   use v5.26;
   use feature 'signatures';

   async sub quart($x, $y)
   {
      ...
   }

I any exceptions thrown by signature validation (because
of too few or too many arguments being passed) are thrown synchronously, and
do not result in a failed Future instance.

=head2 Cancellation

Cancelled futures cause a suspended C to simply stop running.

   async sub fizz
   {
      await func();
      say "This is never reached";
   }

   my $f = fizz();
   $f->cancel;

Cancellation requests can propagate backwards into the future the
C is currently waiting on.

   async sub floof
   {
      ...
      await $f1;
   }

   my $f2 = floof();

   $f2->cancel;  # $f1 will be cancelled too

This behaviour is still more experimental than the rest of the logic. The
following should be noted:

=over 4

=item *

Cancellation propagation is only implemented on Perl version 5.24 and above.
An C in an earlier perl version will still stop executing if
cancelled, but will not propagate the request backwards into the future that
the C is currently waiting on. See L.

=back

=head1 SUBCLASSING Future

By default when an C returns a result or fails immediately before
awaiting, it will return a new completed instance of the L class. In
order to allow code that wishes to use a different class to represent futures
the module import method can be passed the name of a class to use instead.

   use Future::AsyncAwait future_class => "Subclass::Of::Future";

   async sub func { ... }

This has the usual lexically-scoped effect, applying only to Cs
defined within the block; others are unaffected.

   use Future::AsyncAwait;

   {
      use Future::AsyncAwait future_class => "Different::Future";
      async sub x { ... }
   }

   async sub y { ... }  # returns a regular Future

This will only affect immediate results. If the C keyword has to
suspend the function and create a new pending future, it will do this by using
the prototype constructor on the future it itself is waiting on, and the usual
subclass-respecting semantics of L will remain in effect there. As
such it is not usually necessary to use this feature just for wrapping event
system modules or other similar situations.

Such an alternative subclass should implement the API documented by
L.

=head1 WITH OTHER MODULES

=head2 Syntax::Keyword::Try

As of L version 0.10 and L version
0.07, cross-module integration tests assert that basic C blocks
inside an C work correctly, including those that attempt to
C from inside C.

   use Future::AsyncAwait;
   use Syntax::Keyword::Try;

   async sub attempt
   {
      try {
         await func();
         return "success";
      }
      catch {
         return "failed";
      }
   }

As of L version 0.50, C blocks are invoked even
during cancellation.

=head2 Syntax::Keyword::Dynamically

As of L version 0.32, cross-module integration tests
assert that the C correctly works across an C boundary.

   use Future::AsyncAwait;
   use Syntax::Keyword::Dynamically;

   our $var;

   async sub trial
   {
      dynamically $var = "value";

      await func();

      say "Var is still $var";
   }

=head2 Syntax::Keyword::Defer

As of L version 0.50, C blocks are invoked even
during cancellation.

   use Future::AsyncAwait;
   use Syntax::Keyword::Defer;

   async sub perhaps
   {
      defer { say "Cleaning up now" }
      await $f1;
   }

   my $fouter = perhaps();
   $fouter->cancel;

=head2 Object::Pad

As of L version 0.38 and L version 0.15, both
modules now use L to parse blocks of code. Because of this
the two modules can operate together and allow class methods to be written as
async subs which await expressions:

   use Future::AsyncAwait;
   use Object::Pad;

   class Example
   {
      async method perform($block)
      {
         say "$self is performing code";
         await $block->();
         say "code finished";
      }
   }

=head2 Syntax::Keyword::MultiSub

As of L version 0.55 and L
version 0.02 a cross-module integration test asserts that the C
modifier can be applied to C.

   use Future::AsyncAwait;
   use Syntax::Keyword::MultiSub;

   async multi sub f () { return "nothing"; }
   async multi sub f ($key) { return await get_thing($key); }

=cut

sub import
{
   my $pkg = shift;
   my $caller = caller;

   $pkg->import_into( $caller, @_ );
}

sub unimport
{
   my $pkg = shift;
   my $caller = caller;

   $pkg->unimport_into( $caller, @_ );
}

sub import_into   { shift->apply( sub { $^H{ $_[0] }++ },      @_ ) }
sub unimport_into { shift->apply( sub { delete $^H{ $_[0] } }, @_ ) }

my @EXPERIMENTAL = qw( cancel );

sub apply
{
   my $pkg = shift;
   my ( $cb, $caller, @syms ) = @_;

   $cb->( "Future::AsyncAwait/async" ); # Just always turn this on

   SYM: while( @syms ) {
      my $sym = shift @syms;

      $^H{"Future::AsyncAwait/future"} = shift @syms, next if $sym eq "future_class";

      foreach ( @EXPERIMENTAL ) {
         $cb->( "Future::AsyncAwait/experimental($_)" ), next SYM if $sym eq ":experimental($_)";
      }
      if( $sym eq ":experimental" ) {
         $cb->( "Future::AsyncAwait/experimental($_)" ) for @EXPERIMENTAL;
         next SYM;
      }

      croak "Unrecognised import symbol $sym";
   }
}

=head1 SEE ALSO

=over 4

=item *

"Awaiting The Future" - TPC in Amsterdam 2017

L L<(slides)|https://docs.google.com/presentation/d/13x5l8Rohv_RjWJ0OTvbsWMXKoNEWREZ4GfKHVykqUvc/edit#slide=id.p>

=back

=head1 TODO

=over 4

=item *

Suspend and resume with some consideration for the savestack; i.e. the area
used to implement C and similar. While in general C support has
awkward questions about semantics, there are certain situations and cases
where internally-implied localisation of variables would still be useful and
can be supported without the semantic ambiguities of generic C.

   our $DEBUG = 0;

   async sub quark
   {
      local $DEBUG = 1;
      await func();
   }

Since C loops on non-lexical iterator variables (usually the C<$_>
global variable) effectively imply a C-like behaviour, these are also
disallowed.

   async sub splurt
   {
      foreach ( LIST ) {
         await ...
      }
   }

Some notes on what makes the problem hard can be found at

L

=item *

Currently this module requires perl version 5.16 or later. Additionally,
threaded builds of perl earlier than 5.22 are not supported.

L

L

=item *

Implement cancel back-propagation for Perl versions earlier than 5.24.
Currently this does not work due to some as-yet-unknown effects that
installing the back-propagation has, causing future instances to be reclaimed
too early.

L

=back

=head1 KNOWN BUGS

This is not a complete list of all known issues, but rather a summary of the
most notable ones that currently prevent the module from working correctly in
a variety of situations. For a complete list of known bugs, see the RT queue
at L.

=over 4

=item *

C inside C or C blocks does not work. This is due to the
difficulty of detecting the map or grep context from internal perl state at
suspend time, sufficient to be able to restore it again when resuming.

L

As a workaround, consider converting a C expression to the equivalent
form using C onto an accumulator array with a C loop:

   my @results = map { await func($_) } ITEMS;

becomes

   my @results;
   foreach my $item ( ITEMS ) {
      push @results, await func($item);
   }

with a similar transformation for C expressions.

Alternatively, consider using the C family of functions from
L to provide a concurrent version of the same code, which can
keep multiple items running concurrently:

   use Future::Utils qw( fmap );

   my @results = await fmap { func( shift ) }
      foreach    => [ ITEMS ],
      concurrent => 5;

=item *

The default arguments array (C<@_>) is not saved and restored by an C
call on perl versions before v5.24. On such older perls, the value seen in the
C<@_> array after an await will not be the same as it was before.

L

As a workaround, make sure to unpack the values out of it into regular lexical
variables early on, before the the first C. The values of these
lexicals will be saved and restored as normal.

   async sub f
   {
      my ($vars, $go, @here) = @_;
      # do not make further use of @_ afterwards

      await thing();

      # $vars, $go, @here are all fine for use
   }

=back

=cut

=head1 ACKNOWLEDGEMENTS

With thanks to C, C and others from C for
assisting with trickier bits of XS logic.

Thanks to C for project management and actually reminding me to write
some code.

Thanks to The Perl Foundation for sponsoring me to continue working on the
implementation.

=head1 AUTHOR

Paul Evans

=cut

0x55AA;