| 1 | use strict; | ||
| 2 | use 5.010; | ||
| 3 | |||
| 4 | =head1 NAME | ||
| 5 | |||
| 6 | FusqlFS::Backend::PgSQL::Table::Triggers | ||
| 7 | |||
| 8 | =head1 SYNOPSIS | ||
| 9 | |||
| 10 | use FusqlFS::Backend::PgSQL::Table::Triggers | ||
| 11 | |||
| 12 | my $triggers = FusqlFS::Backend::PgSQL::Table::Triggers->new(); | ||
| 13 | |||
| 14 | =head1 DESCRIPTION | ||
| 15 | |||
| 16 | =head1 EXPOSED STRUCTURE | ||
| 17 | |||
| 18 | =over | ||
| 19 | |||
| 20 | =item F<./handler> | ||
| 21 | |||
| 22 | Symlink to function in F<../../../../functions>, which executes on trigger event(s). | ||
| 23 | |||
| 24 | =item F<./create.sql> | ||
| 25 | |||
| 26 | C<CREATE TRIGGER> clause to create this trigger. | ||
| 27 | |||
| 28 | =item F<./struct> | ||
| 29 | |||
| 30 | Additional trigger info with following fields: | ||
| 31 | |||
| 32 | =over | ||
| 33 | |||
| 34 | =item C<for_each> | ||
| 35 | |||
| 36 | I<one of row or statement> defines if trigger will be triggered for each touched row or once for whole statement. | ||
| 37 | |||
| 38 | =item C<when> | ||
| 39 | |||
| 40 | I<one of before or after> defines if trigger is triggered before or after event(s). | ||
| 41 | |||
| 42 | =item C<events> | ||
| 43 | |||
| 44 | I<set of insert, update, delete, truncate> list of events trigger will be triggered on. | ||
| 45 | |||
| 46 | =back | ||
| 47 | |||
| 48 | =back | ||
| 49 | |||
| 50 | =head1 METHODS | ||
| 51 | |||
| 52 | =over | ||
| 53 | |||
| 54 | =cut | ||
| 55 | |||
| 56 | package FusqlFS::Backend::PgSQL::Table::Triggers; | ||
| 57 | use FusqlFS::Version; | ||
| 58 | our $VERSION = $FusqlFS::Version::VERSION; | ||
| 59 | use parent 'FusqlFS::Artifact::Table::Lazy'; | ||
| 60 | |||
| 61 | =item new | ||
| 62 | |||
| 63 | Class constructor. | ||
| 64 | |||
| 65 | Output: $triggers_instance. | ||
| 66 | |||
| 67 | =begin testing new | ||
| 68 | |||
| 69 | my $triggers = {_tpkg}->new(); | ||
| 70 | isa_ok $triggers, $_tcls; | ||
| 71 | |||
| 72 | =end testing | ||
| 73 | =cut | ||
| 74 | sub init | ||
| 75 | { | ||
| 76 | my $self = shift; | ||
| 77 | |||
| 78 | # tgtype: | ||
| 79 | # 0 1 = for each row | ||
| 80 | # 1 2 = before | ||
| 81 | # 2 4 = insert | ||
| 82 | # 3 8 = delete | ||
| 83 | # 4 16 = update | ||
| 84 | # 5 32 = truncate (?) | ||
| 85 | $self->{get_expr} = $self->expr('SELECT pg_catalog.pg_get_triggerdef(t.oid) AS "create.sql", | ||
| 86 | p.proname||\'(\'||pg_catalog.pg_get_function_arguments(p.oid)||\')\' AS handler, | ||
| 87 | CASE WHEN (t.tgtype & 1) != 0 THEN \'row\' ELSE \'statement\' END AS for_each, | ||
| 88 | CASE WHEN (t.tgtype & 2) != 0 THEN \'before\' ELSE \'after\' END AS when, | ||
| 89 | ARRAY[ | ||
| 90 | CASE WHEN (t.tgtype & 4) != 0 THEN \'insert\' END, | ||
| 91 | CASE WHEN (t.tgtype & 8) != 0 THEN \'delete\' END, | ||
| 92 | CASE WHEN (t.tgtype & 16) != 0 THEN \'update\' END, | ||
| 93 | CASE WHEN (t.tgtype & 32) != 0 THEN \'truncate\' END | ||
| 94 | ] AS events | ||
| 95 | FROM pg_catalog.pg_trigger AS t | ||
| 96 | LEFT JOIN pg_catalog.pg_class AS r ON (t.tgrelid = r.oid) | ||
| 97 | LEFT JOIN pg_catalog.pg_proc AS p ON (t.tgfoid = p.oid) | ||
| 98 | WHERE r.relname = ? AND t.tgname = ? AND t.tgconstraint = 0'); | ||
| 99 | $self->{list_expr} = $self->expr('SELECT t.tgname FROM pg_catalog.pg_trigger AS t | ||
| 100 | LEFT JOIN pg_catalog.pg_class AS r ON (t.tgrelid = r.oid) WHERE r.relname = ?'); | ||
| 101 | |||
| 102 | $self->{rename_expr} = 'ALTER TRIGGER %s ON %s RENAME TO %s'; | ||
| 103 | $self->{drop_expr} = 'DROP TRIGGER %s ON %s'; | ||
| 104 | $self->{store_expr} = 'CREATE TRIGGER %s %s %s ON %s FOR EACH %s EXECUTE PROCEDURE %s'; | ||
| 105 | |||
| 106 | $self->{template} = { | ||
| 107 | 'struct' => $self->dump({ | ||
| 108 | events => [ | ||
| 109 | 'insert', | ||
| 110 | 'update', | ||
| 111 | 'delete', | ||
| 112 | ], | ||
| 113 | for_each => 'row', | ||
| 114 | when => 'before', | ||
| 115 | }), | ||
| 116 | }; | ||
| 117 | } | ||
| 118 | |||
| 119 | =item get | ||
| 120 | |||
| 121 | =begin testing get | ||
| 122 | |||
| 123 | is $_tobj->get('fusqlfs_table', 'xxxxx'), undef; | ||
| 124 | is $_tobj->get('xxxxx', 'xxxxx'), undef; | ||
| 125 | |||
| 126 | =end testing | ||
| 127 | =cut | ||
| 128 | sub get | ||
| 129 | { | ||
| 130 | my $self = shift; | ||
| 131 | my ($table, $name) = @_; | ||
| 132 | |||
| 133 | unless ($self->SUPER::get($table, $name)) | ||
| 134 | { | ||
| 135 | my $data = $self->one_row($self->{get_expr}, $table, $name); | ||
| 136 | return unless $data; | ||
| 137 | |||
| 138 | my $result = {}; | ||
| 139 | |||
| 140 | $data->{events} = [ grep $_, @{$data->{events}} ]; | ||
| 141 | |||
| 142 | $result->{handler} = \"functions/$data->{handler}"; | ||
| 143 | delete $data->{handler}; | ||
| 144 | |||
| 145 | $result->{'create.sql'} = delete($data->{'create.sql'}); | ||
| 146 | $result->{struct} = $self->dump($data); | ||
| 147 | |||
| 148 | return $result; | ||
| 149 | } | ||
| 150 | } | ||
| 151 | |||
| 152 | =item list | ||
| 153 | |||
| 154 | =begin testing list | ||
| 155 | |||
| 156 | cmp_set $_tobj->list('fusqlfs_table'), []; | ||
| 157 | |||
| 158 | =end testing | ||
| 159 | =cut | ||
| 160 | sub list | ||
| 161 | { | ||
| 162 | my $self = shift; | ||
| 163 | my ($table) = @_; | ||
| 164 | return [ @{$self->all_col($self->{list_expr}, $table)}, @{$self->SUPER::list($table)} ]; | ||
| 165 | } | ||
| 166 | |||
| 167 | =item drop | ||
| 168 | |||
| 169 | =begin testing drop after rename | ||
| 170 | |||
| 171 | is $_tobj->drop('fusqlfs_table', 'fusqlfs_trigger'), undef; | ||
| 172 | isnt $_tobj->drop('fusqlfs_table', 'new_fusqlfs_trigger'), undef; | ||
| 173 | cmp_set $_tobj->list('fusqlfs_table'), []; | ||
| 174 | is $_tobj->get('fusqlfs_table', 'fusqlfs_trigger'), undef; | ||
| 175 | |||
| 176 | =end testing | ||
| 177 | =cut | ||
| 178 | sub drop | ||
| 179 | { | ||
| 180 | my $self = shift; | ||
| 181 | my ($table, $name) = @_; | ||
| 182 | $self->SUPER::drop($table, $name) or $self->do($self->{drop_expr}, [$name, $table]); | ||
| 183 | } | ||
| 184 | |||
| 185 | =item store | ||
| 186 | |||
| 187 | =begin testing store after get list | ||
| 188 | |||
| 189 | isnt $_tobj->create('fusqlfs_table', 'fusqlfs_trigger'), undef; | ||
| 190 | cmp_set $_tobj->list('fusqlfs_table'), [ 'fusqlfs_trigger' ]; | ||
| 191 | is_deeply $_tobj->get('fusqlfs_table', 'fusqlfs_trigger'), $_tobj->{template}; | ||
| 192 | |||
| 193 | isnt $_tobj->store('fusqlfs_table', 'fusqlfs_trigger', $new_trigger), undef; | ||
| 194 | cmp_set $_tobj->list('fusqlfs_table'), [ 'fusqlfs_trigger' ]; | ||
| 195 | is_deeply $_tobj->get('fusqlfs_table', 'fusqlfs_trigger'), $new_trigger; | ||
| 196 | |||
| 197 | =end testing | ||
| 198 | =cut | ||
| 199 | sub store | ||
| 200 | { | ||
| 201 | my $self = shift; | ||
| 202 | my ($table, $name, $data) = @_; | ||
| 203 | return unless $data; | ||
| 204 | |||
| 205 | my $struct = $self->validate($data, { | ||
| 206 | struct => { | ||
| 207 | when => qr/^(before|after)$/i, | ||
| 208 | for_each => qr/^(row|statement)$/i, | ||
| 209 | events => $self->set_of(qw(insert update delete truncate)), | ||
| 210 | }, | ||
| 211 | handler => ['SCALAR', sub{ $$_ =~ /^functions\/(\S+\(.*\))$/ && $1 }] | ||
| 212 | }) or return; | ||
| 213 | |||
| 214 | my $when = uc($struct->{struct}->{when}); | ||
| 215 | my $for_each = uc($struct->{struct}->{for_each}); | ||
| 216 | my $events = join ' OR ', map { uc $_ } @{$struct->{struct}->{events}}; | ||
| 217 | my $handler = $struct->{handler}; | ||
| 218 | |||
| 219 | $self->drop($table, $name) and $self->do($self->{store_expr}, [$name, $when, $events, $table, $for_each, $handler]); | ||
| 220 | } | ||
| 221 | |||
| 222 | =item rename | ||
| 223 | |||
| 224 | =begin testing rename after store | ||
| 225 | |||
| 226 | isnt $_tobj->rename('fusqlfs_table', 'fusqlfs_trigger', 'new_fusqlfs_trigger'), undef; | ||
| 227 | is $_tobj->get('fusqlfs_table', 'fusqlfs_trigger'), undef; | ||
| 228 | $new_trigger->{'create.sql'} =~ s/TRIGGER fusqlfs_trigger/TRIGGER new_fusqlfs_trigger/; | ||
| 229 | is_deeply $_tobj->get('fusqlfs_table', 'new_fusqlfs_trigger'), $new_trigger; | ||
| 230 | cmp_set $_tobj->list('fusqlfs_table'), [ 'new_fusqlfs_trigger' ]; | ||
| 231 | |||
| 232 | =end testing | ||
| 233 | =cut | ||
| 234 | sub rename | ||
| 235 | { | ||
| 236 | my $self = shift; | ||
| 237 | my ($table, $name, $newname) = @_; | ||
| 238 | $self->SUPER::rename($table, $name, $newname) | ||
| 239 | or $self->do($self->{rename_expr}, [$name, $table, $newname]); | ||
| 240 | } | ||
| 241 | |||
| 242 | 1; | ||
| 243 | |||
| 244 | __END__ |