File Coverage

blib/lib/Freecell/Deal/MS.pm

Criterion	Covered	Total	%
statement	30	30	100.0
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod	2	2	100.0
total	39	39	100.0

package Freecell::Deal::MS;
$Freecell::Deal::MS::VERSION = '0.6.0';
use strict;
use warnings;

use Math::RNG::Microsoft::FCPro ();

use Class::XSAccessor {
    constructor => 'new',
    accessors   => [qw(deal)],
};

my @INITIAL_CARDS = (
    map {
        my $s = $_;
        map { $s . $_ } qw/C D H S/;
    } ( 'A', ( 2 .. 9 ), 'T', 'J', 'Q', 'K' )
);

sub _string_arrays
{
    my ($self) = @_;

    my @cards = @INITIAL_CARDS;
    Math::RNG::Microsoft::FCPro->new( seed => scalar( $self->deal ) )
        ->shuffle( \@cards );
    my @lines = ( map { [] } 0 .. 7 );
    my $i     = -1;
    while (@cards)
    {
        push @{ $lines[ ( ( ++$i ) & 7 ) ] }, pop(@cards);
    }
    return \@lines;
}

sub as_columns_array
{
    my ($self) = @_;

    my $rec =
        { array_of_arrays_of_strings => scalar( $self->_string_arrays() ), };

    return $rec;
}

sub as_str
{
    my ($self) = @_;

    my $lines = scalar( $self->_string_arrays() );
    my $str   = join "", map { ": @$_\n" } @$lines;
    return $str;
}

1;

__END__