File Coverage

blib/lib/Form/Tiny/Error.pm

Criterion	Covered	Total	%
statement	56	60	93.3
branch	2	2	100.0
condition	5	5	100.0
subroutine	20	23	86.9
pod	0	6	0.0
total	83	96	86.4

package Form::Tiny::Error;
$Form::Tiny::Error::VERSION = '2.26';
use v5.10;
use strict;
use warnings;
use Moo;
use Types::Standard qw(Maybe Str InstanceOf);
use Types::TypeTiny qw(StringLike);
use Carp qw(confess);

use overload
	q{""} => 'as_string',
	fallback => 1;

has 'field_def' => (
	is => 'ro',
	isa => InstanceOf['Form::Tiny::FieldDefinition'],
	writer => 'set_field_def',
	predicate => 'has_field_def',
);

has 'field' => (
	is => 'ro',
	isa => Str,
	writer => 'set_field',
	predicate => 'has_field',
);

has 'error' => (
	is => 'ro',
	isa => StringLike,
	writer => 'set_error',
	builder => 'default_error',
);

sub BUILD
{
	my ($self) = @_;

	if (!$self->field && $self->field_def) {
		$self->set_field($self->field_def->name);
	}
}

sub default_error
{
	confess 'no error message supplied';
	return 'Unknown error';
}

sub get_error
{
	my ($self) = @_;

	return $self->error;
}

sub as_string
{
	my ($self) = @_;

	my $field = $self->field // 'general';
	my $error = $self->get_error;
	return "$field - $error";
}

# in-place subclasses
{

	# Internal use only
	package Form::Tiny::Error::NestedFormError;
$Form::Tiny::Error::NestedFormError::VERSION = '2.26';
use parent -norequire, 'Form::Tiny::Error';

}

{

	package Form::Tiny::Error::InvalidFormat;
$Form::Tiny::Error::InvalidFormat::VERSION = '2.26';
use parent -norequire, 'Form::Tiny::Error';

	sub default_error
	{
		return 'input data format is invalid';
	}
}

{

	package Form::Tiny::Error::Required;
$Form::Tiny::Error::Required::VERSION = '2.26';
use parent -norequire, 'Form::Tiny::Error';

	sub default_error
	{
		return 'field is required';
	}
}

{

	package Form::Tiny::Error::IsntStrict;
$Form::Tiny::Error::IsntStrict::VERSION = '2.26';
use Moo;
	use Types::Standard qw(Str);

	extends 'Form::Tiny::Error';

	has 'extra_field' => (
		is => 'ro',
		isa => Str,
		required => 1,
	);

	sub default_error
	{
		return 'input data has unexpected fields';
	}

	sub get_error
	{
		my ($self) = @_;

		my $field = $self->extra_field;
		my $error = $self->error;
		return "$field: $error";
	}
}

{

	package Form::Tiny::Error::DoesNotValidate;
$Form::Tiny::Error::DoesNotValidate::VERSION = '2.26';
use parent -norequire, 'Form::Tiny::Error';

	sub default_error
	{
		return 'data validation failed';
	}
}

1;

__END__