File Coverage

blib/lib/Filename/Type/Backup.pm

Criterion	Covered	Total	%
statement	31	31	100.0
branch	9	10	90.0
condition	2	2	100.0
subroutine	5	5	100.0
pod	1	1	100.0
total	48	49	97.9

package Filename::Type::Backup;

use 5.010001;
use strict;
use warnings;

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-12-20'; # DATE
our $DIST = 'Filename-Type-Backup'; # DIST
our $VERSION = '0.040'; # VERSION

use Exporter qw(import);
our @EXPORT_OK = qw(check_backup_filename);

our %SPEC;

our %SUFFIXES = (
    '~'     => 1,
    '.bak'  => 1,
    '.old'  => 1,
    '.orig' => 1, # patch
    '.rej'  => 1, # patch
    '.swp'  => 1,
    # XXX % (from /etc/mime.types)
    # XXX sik? (from /etc/mime.types)
    # XXX .dpkg*
    # XXX .rpm*
);

$SPEC{check_backup_filename} = {
    v => 1.1,
    summary => 'Check whether filename indicates being a backup file',
    description => <<'MARKDOWN',


MARKDOWN
    args => {
        filename => {
            schema => 'str*',
            req => 1,
            pos => 0,
        },
        # XXX recurse?
        ci => {
            summary => 'Whether to match case-insensitively',
            schema  => 'bool',
            default => 1,
        },
    },
    result_naked => 1,
    result => {
        schema => ['any*', of=>['bool*', 'hash*']],
        description => <<'MARKDOWN',

Return false if not detected as backup name. Otherwise return a hash, which may
contain these keys: `original_filename`. In the future there will be extra
information returned, e.g. editor name (if filename indicates backup from
certain backup program), date (if filename contains date information), and so
on.

MARKDOWN
    },
};
sub check_backup_filename {
    my %args = @_;

    my $filename = $args{filename};
    my $orig_filename;

    if ($filename =~ /\A#(.+)#\z/) {
        $orig_filename = $1;
        goto RETURN;
    }

    $filename =~ /(~|\.\w+)\z/ or return 0;
    my $ci = $args{ci} // 1;

    my $suffix = $1;

    my $spec;
    if ($ci) {
        my $suffix_lc = lc($suffix);
        for (keys %SUFFIXES) {
            if (lc($_) eq $suffix_lc) {
                $spec = $SUFFIXES{$_};
                last;
            }
        }
    } else {
        $spec = $SUFFIXES{$suffix};
    }
    return 0 unless $spec;

    ($orig_filename = $filename) =~ s/\Q$suffix\E\z//;

  RETURN:
    return {
        original_filename => $orig_filename,
    };
}

1;
# ABSTRACT: Check whether filename indicates being a backup file

__END__