File Coverage

blib/lib/ExtUtils/Helpers.pm

Criterion	Covered	Total	%
statement	34	34	100.0
branch			n/a
condition	5	12	41.6
subroutine	9	9	100.0
pod	2	2	100.0
total	50	57	87.7

package ExtUtils::Helpers;
$ExtUtils::Helpers::VERSION = '0.028';
use strict;
use warnings FATAL => 'all';
use Exporter 5.57 'import';

use Config;
use File::Basename qw/basename/;
use File::Spec::Functions qw/splitpath canonpath abs2rel splitdir/;

our @EXPORT_OK = qw/make_executable split_like_shell man1_pagename man3_pagename detildefy/;

BEGIN {
	my %impl_for = ( MSWin32 => 'Windows', VMS => 'VMS');
	my $package = 'ExtUtils::Helpers::' . ($impl_for{$^O} || 'Unix');
	my $impl = $impl_for{$^O} || 'Unix';
	require "ExtUtils/Helpers/$impl.pm";
	"ExtUtils::Helpers::$impl"->import();
}

sub man1_pagename {
	my ($filename, $ext) = @_;
	$ext ||= $Config{man1ext};
	return basename($filename).".$ext";
}

my %separator = (
	MSWin32 => '.',
	VMS => '__',
	os2 => '.',
	cygwin => '.',
);
my $separator = $separator{$^O} || '::';

sub man3_pagename {
	my ($filename, $base, $ext) = @_;
	$base ||= 'lib';
	$ext  ||= $Config{man3ext};
	my ($vols, $dirs, $file) = splitpath(canonpath(abs2rel($filename, $base)));
	$file = basename($file, qw/.pm .pod/);
	my @dirs = grep { length } splitdir($dirs);
	return join $separator, @dirs, "$file.$ext";
}

1;

# ABSTRACT: Various portability utilities for module builders

__END__