File Coverage

blib/lib/ExtUtils/Config.pm

Criterion	Covered	Total	%
statement	29	32	90.6
branch	5	6	83.3
condition	1	6	16.6
subroutine	9	10	90.0
pod	7	7	100.0
total	51	61	83.6

package ExtUtils::Config;
$ExtUtils::Config::VERSION = '0.010';
use strict;
use warnings;
use Config;

sub new {
	my ($pack, $args) = @_;
	return bless {
		values => ($args ? { %$args } : {}),
	}, $pack;
}

sub get {
	my ($self, $key) = @_;
	return exists $self->{values}{$key} ? $self->{values}{$key} : $Config{$key};
}

sub exists {
	my ($self, $key) = @_;
	return exists $self->{values}{$key} || exists $Config{$key};
}

sub values_set {
	my $self = shift;
	return { %{$self->{values}} };
}

sub all_config {
	my $self = shift;
	return { %Config, %{ $self->{values}} };
}

sub serialize {
	my $self = shift;
	require Data::Dumper;
	return $self->{serialized} ||= Data::Dumper->new([ $self->{values} ])->Terse(1)->Sortkeys(1)->Dump;
}

sub but {
	my ($self, $args) = @_;
	my %new = %{ $self->{values} };
	for my $key (keys %$args) {
		if (defined $args->{$key}) {
			$new{$key} = $args->{$key}
		}
		else {
			delete $new{$key};
		}
	}
	return bless { values => \%new }, ref $self;
}

1;

# ABSTRACT: A wrapper for perl's configuration

__END__