File Coverage

blib/lib/ExtUtils/Builder/BuildTools/Base.pm

Criterion	Covered	Total	%
statement	52	60	86.6
branch	12	20	60.0
condition	12	19	63.1
subroutine	16	16	100.0
pod	0	1	0.0
total	92	116	79.3

package ExtUtils::Builder::BuildTools::Base;
$ExtUtils::Builder::BuildTools::Base::VERSION = '0.036';
use strict;
use warnings;

use parent 'ExtUtils::Builder::Planner::Extension';

use Carp 'croak';
use File::Spec::Functions 'catfile';

sub add_methods {
	my ($class, $planner, %opts) = @_;

	$opts{type} //= 'executable';

	my $compiler_as = delete $opts{compiler_as} // 'compile';
	$planner->add_delegate($compiler_as, sub {
		my ($planner, $from, $to, %extra) = @_;
		my %args = (%opts, %extra);

		my $compiler = $class->make_compiler(\%args);

		$args{profiles} = [ delete $args{profile} ] if $args{profile} and not $args{profiles};
		for my $profile (@{ $args{profiles} // [] }) {
			$compiler->add_profile($profile, %args);
		}

		if (my $include_dirs = $args{include_dirs}) {
			$compiler->add_include_dirs($include_dirs);
		}
		if (my $defines = $args{defines}) {
			$compiler->add_defines($defines);
		}
		if (my $extra = $args{extra_args}) {
			$compiler->add_argument(value => $extra);
		}
		if (my $standard = $args{standard}) {
			$compiler->set_standard($standard);
		}

		my $node = $compiler->compile($from, $to, %args);
		return $planner->add_node($node);
	});

	my $linker_as = delete $opts{linker_as} // 'link';
	$planner->add_delegate($linker_as, sub {
		my ($planner, $from, $to, %extra) = @_;
		my %args = (%opts, %extra);

		my $linker = $class->make_linker(\%args);

		$args{profiles} = [ delete $args{profile} ] if $args{profile} and not $args{profiles};
		for my $profile (@{ $args{profiles} // [] }) {
			$linker->add_profile($profile, %args);
		}

		if (my $library_dirs = $args{library_dirs}) {
			$linker->add_library_dirs($library_dirs);
		}
		if (my $libraries = $args{libraries}) {
			$linker->add_libraries($libraries);
		}
		if (my $extra_args = $args{extra_args}) {
			$linker->add_argument(ranking => 85, value => [ @{$extra_args} ]);
		}

		my $node = $linker->link($from, $to, %args);
		return $planner->add_node($node);
	});

	for my $name (qw/object_file library_file static_library_file loadable_file executable_file/) {
		my $format = delete $opts{$name} // croak "No known extension for $name";
		$planner->add_delegate($name, sub {
			my ($planner, $file, $dir) = @_;
			my $filename = sprintf $format, $file;
			return defined $dir ? catfile($dir, $filename) : $filename;
		});
	}
}

1;

# ABSTRACT: A base class for BuildTools implementations.

__END__