File Coverage

blib/lib/Exporter/Lexical.pm

Criterion	Covered	Total	%
statement	43	43	100.0
branch	3	4	75.0
condition	2	3	66.6
subroutine	10	10	100.0
pod	1	1	100.0
total	59	61	96.7

package Exporter::Lexical;
BEGIN {
  $Exporter::Lexical::AUTHORITY = 'cpan:DOY';
}
{
  $Exporter::Lexical::VERSION = '0.02';
}
use strict;
use warnings;
use 5.018;
# ABSTRACT: exporter for lexical subs


use XSLoader;
XSLoader::load(
    __PACKAGE__,
    # we need to be careful not to touch $VERSION at compile time, otherwise
    # DynaLoader will assume it's set and check against it, which will cause
    # fail when being run in the checkout without dzil having set the actual
    # $VERSION
    exists $Exporter::Lexical::{VERSION}
        ? ${ $Exporter::Lexical::{VERSION} } : (),
);

sub import {
    my $package = shift;
    my %opts = @_;

    my $caller = caller;

    my $import = build_exporter(\%opts, $caller);

    {
        no strict 'refs';
        *{ $caller . '::import' } = $import;
    }
}


sub build_exporter {
    my ($opts, $caller) = @_;
    $caller //= caller;

    return sub {
        my $caller_stash = do {
            no strict 'refs';
            \%{ $caller . '::' };
        };
        my %exports;
        if (ref($opts->{'-exports'}) eq 'ARRAY') {
            %exports = map { $_ => \&{ $caller_stash->{$_} } }
                           @{ $opts->{'-exports'} };
        }
        elsif (ref($opts->{'-exports'}) eq 'HASH') {
            %exports = %{ $opts->{'-exports'} };
        }

        for my $export (keys %exports) {
            lexical_import($export, $exports{$export});
        }

        # XXX there is a bug with lexical_import where the pad entry sequence
        # numbers are incorrect when used with 'use', so the first statement
        # after the 'use' statement doesn't see the lexical. hack around this
        # for now by injecting a dummy statement right after the 'use'.
        _lex_stuff(";1;");
    };
}



1;

__END__