File Coverage

blib/lib/Encode/Base58/BigInt.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	4	4	100.0
condition			n/a
subroutine	7	7	100.0
pod	0	2	0.0
total	46	48	95.8

package Encode::Base58::BigInt;
use strict;
use warnings;

our $VERSION = '0.03';
use Math::BigInt;
use Carp;

use base qw(Exporter);
our @EXPORT = qw( encode_base58 decode_base58 );

# except 0 O D / 1 l I
my $chars = [qw(
    1 2 3 4 5 6 7 8 9
    a b c d e f g h i
    j k m n o p q r s
    t u v w x y z A B
    C D E F G H J K L
    M N P Q R S T U V
    W X Y Z
)];

my $reg = qr/^[@{[ join "", @$chars ]}]+$/;

my $map = do {
    my $i = 0;
    +{ map { $_ => $i++ } @$chars };
};

sub encode_base58 {
    my ($num) = @_;
    return $chars->[0] unless $num;

    $num = Math::BigInt->new($num);

    my $res = '';
    my $base = @$chars;

    while ($num->is_pos) {
        my ($quo, $rem) = $num->bdiv($base);
        $res = $chars->["$rem"] . $res;
    }

    $res;
}

sub decode_base58 {
    my $str = shift;
    $str =~ tr/0OlI/DD11/;
    $str =~ $reg or croak "Invalid Base58";

    my $decoded = Math::BigInt->new(0);
    my $multi   = Math::BigInt->new(1);
    my $base    = @$chars;

    while (length $str > 0) {
        my $digit = chop $str;
        $decoded->badd($multi->copy->bmul($map->{$digit}));
        $multi->bmul($base);
    }

    "$decoded";
}

1;
__END__