File Coverage

blib/lib/EB.pm

Criterion	Covered	Total	%
statement	59	82	71.9
branch	14	32	43.7
condition	4	11	36.3
subroutine	14	16	87.5
pod	0	3	0.0
total	91	144	63.1

#! perl --			-*- coding: utf-8 -*-

use utf8;

# EB.pm -- EekBoek Base module.
# Author          : Johan Vromans
# Created On      : Fri Sep 16 18:38:45 2005
# Last Modified By: Johan Vromans
# Last Modified On: Tue Jan 31 12:03:31 2017
# Update Count    : 322
# Status          : Unknown, Use with caution!

package main;

our $app;
our $cfg;

package EB;

use strict;
use base qw(Exporter);

use EekBoek;

our @EXPORT;
our @EXPORT_OK;

# Establish location of our run-time resources.
my $lib;
sub libfile {
    my ($f) = @_;

    unless ( $lib ) {
	# Cava.
	if ( $Cava::Packager::PACKAGED ) {
	    return Cava::Packager::GetResourcePath()."/$f";
	}
	else {
	    $lib = $INC{"EB.pm"};
	    $lib =~ s/EB\.pm$//;
	}
    }
    $lib."EB/res/$f";
}

sub findlib {
    my ($file, $section) = @_;

    # The two-argument form supports locale-dependent paths, but
    # we hard-wire this to 'nl'.
    if ( $section ) {
	my $lang = 'nl';
	my $found = findlib( "$section/$lang/$file" );
	return $found if $found;
	$found = findlib( "$section/$file" );
	return $found if $found;
	return undef;
    }

    # Cava.
    if ( $Cava::Packager::PACKAGED ) {
	my $found = Cava::Packager::GetUserFile($file);
	return $found if -e $found;
	$found = Cava::Packager::GetResource($file);
	return $found if -e $found;
    }

    foreach ( @INC ) {
	return "$_/EB/user/$file" if -e "$_/EB/user/$file";
	return "$_/EB/res/$file" if -e "$_/EB/res/$file";
	return "$_/EB/$file" if -e "$_/EB/$file";
    }
    undef;
}

use lib ( grep { defined } findlib("CPAN") );

# Some standard modules (locale-free).
use EB::Globals;
use Carp;
use Data::Dumper;
use Carp::Assert;
use EB::Utils;

# Even though we do not use translations, most of the code is in place.
sub _T { $_[0] }

# Export our and the imported globals.
@EXPORT = ( @EB::Globals::EXPORT,
	    @EB::Utils::EXPORT,
	    "_T",			# @EB::Locale::EXPORT,
	    qw(carp croak),		# Carp
	    qw(Dumper),			# Data::Dumper
	    qw(findlib libfile),	#
	    qw(assert affirm),		# Carp::Assert
	  );

our $ident;
our $imsg;
my $imsg_saved;
our $url = "http://www.eekboek.nl";

sub __init__ {
    $imsg_saved = $imsg || "";

    my $year = 2005;
    my $thisyear = (localtime(time))[5] + 1900;
    $year .= "-$thisyear" unless $year == $thisyear;
    $ident = __x("{name} {version}",
		 name    => $EekBoek::PACKAGE,
		 version => $EekBoek::VERSION);
    $imsg = __x("{ident}{extra} -- Copyright {year} Squirrel Consultancy",
		ident   => $ident,
		extra   => ($app ? " Wx" : ""),
		year    => $year);
    if ( $imsg ne $imsg_saved
	 && !( @ARGV && $ARGV[0] =~ /-(P|-?printconfig)$/ )
       ) {
	warn($imsg, "\n");
    }

    eval {
	require Win32;
	my @a = Win32::GetOSVersion();
	my ($id, $major) = @a[4,1];
	die unless defined $id;
	warn(_T("EekBoek is VRIJE software, ontwikkeld om vrij over uw eigen gegevens te kunnen beschikken.")."\n");
	warn(_T("Met uw keuze voor het Microsoft Windows besturingssysteem geeft u echter alle vrijheden weer uit handen. Dat is erg triest.")."\n");
    } unless $imsg_saved eq $imsg || $ENV{AUTOMATED_TESTING};

}

sub app_init {
    shift;			# 'EB'

    # Load a config file.
    require EB::Config;
    undef $::cfg;
    EB::Config->init_config( @_ );

    # Main initialisation.
    __init__();

    # Initialise locale-dependent formats.
    require EB::Format;
    EB::Format->init_formats();

    return $::cfg;		# until we've got something better
}

sub EB::Config::Handler::connect_db {
    # Connect to the data base.
    require EB::DB;
    EB::DB::->connect;
}

1;

__END__