File Coverage

blib/lib/EPublisher/Source/Plugin/Dir.pm

Criterion	Covered	Total	%
statement	66	66	100.0
branch	34	34	100.0
condition	6	6	100.0
subroutine	9	9	100.0
pod	1	1	100.0
total	116	116	100.0

package EPublisher::Source::Plugin::Dir;

# ABSTRACT: Dir source plugin

use strict;
use warnings;

use File::Find::Rule;
use File::Basename;
use List::Util qw(first);

use EPublisher::Source::Base;
use EPublisher::Utils::PPI qw(extract_pod extract_package);

our @ISA = qw( EPublisher::Source::Base );

our $VERSION = 1.1;

sub load_source{
    my ($self, $source_path) = @_;

    my $options = $self->_config;

    my $path = $source_path || $options->{path};

    if ( !defined $path ) {
        $self->publisher->debug( "400: No path given" );
        return;
    }

    my @paths = ref $path eq 'ARRAY' ? @{$path} : ($path);
    my @paths_to_use;

    for my $path_to_check ( @paths ) {
        if ( !defined $path_to_check ) {
            $self->publisher->debug( "400: undefined path given" );
            next;
        }
        if ( !-d $path_to_check ) {
            $self->publisher->debug( "400: $path_to_check does not exist" );
            next;
        }

        push @paths_to_use, $path_to_check;
    }

    return if !@paths_to_use;

    my @testrule;
    if ( $options->{testfiles} ) {
        @testrule = (qr/\.t\z/);
    }

    my $rule  = File::Find::Rule->file->name( qr/\.p(?:m|od|l)\z/, @testrule );

    if ( defined $options->{subdirs} && $options->{subdirs} == 0 ) {
        $rule->maxdepth( 1 );
    }

    my @files = sort $rule->in( @paths_to_use );
    my @pods;

    my @excludes;
    if ( $options->{exclude} ) {
        @excludes = ref $options->{exclude} eq 'ARRAY' ? @{ $options->{exclude} } : ($options->{exclude});
    }

    $options->{title} = '' if !defined $options->{title};

    FILE:
    for my $file ( @files ) {

        next FILE if first{ $file =~ m{\A \Q$_\E }xms }@excludes;

        my $pod = extract_pod( $file, $self->_config );

        next FILE if !$pod;

        my $filename = basename $file;
        my $title    = $filename;

        if ( $options->{title} eq 'pod' ) {
            ($title) = $pod =~ m{ =head1 \s+ (.*) }x;
            $title = '' if !defined $title;
        }
        elsif ( $options->{title} eq 'package' ) {
            my $package = extract_package( $file, $self->_config );
            $title = $package if $package;
        }
        elsif ( length $options->{title} ) {
            $title = $options->{title};
        }

        push @pods, { pod => $pod, title => $title, filename => $filename };
    }

    return @pods;
}

1;

__END__