File Coverage

blib/lib/EPublisher.pm

Criterion	Covered	Total	%
statement	68	75	90.6
branch	20	30	66.6
condition	15	21	71.4
subroutine	12	13	92.3
pod	5	5	100.0
total	120	144	83.3

package EPublisher;

# ABSTRACT: Publish documents in new format

use strict;
use warnings;
use Carp;

use EPublisher::Config;
use EPublisher::Source;
use EPublisher::Target;

our $VERSION = 1.26;

sub new{
    my ($class,%args) = @_;
    my $self = bless {}, $class;

    $self->config( $args{config} ) if exists $args{config};
    $self->_debug( $args{debug} );

    return $self;
}

sub config{
    my ($self,$data) = @_;

    my $ref = ref $data;
    if( defined $data and !$ref ){
        $self->{_configfile} = $data;
        $self->_config(1);
    }
    elsif ( $ref and $ref eq 'HASH' ) {
        $self->_config( 1, $data );
    }

    return $self->{_configfile};
}

sub projects {
    my ($self) = @_;

    my $config = $self->_config;

    return if !$config;
    return if !ref $config;
    return if ref $config ne 'HASH';

    return keys %{$config};
}

sub run{
    my ($self,$projects) = @_;

    PROJECT:
    for my $project ( @$projects ){
        my $config   = $self->_config->{$project};

        next PROJECT if !$config;

        # load the source
        my $sources = $config->{source};
        $sources    = [ $sources ] if !ref $sources or ref $sources ne 'ARRAY';

        my @pods;
        for my $source ( @{$sources} ) {
            die('No type in source.') unless (exists $source->{type});
            $self->debug('100: ' . $source->{type} );
            my $source_obj = EPublisher::Source->new( $source );
            $source_obj->publisher( $self );

            my @pod_source = $source_obj->load_source;
            @pod_source = ({ pod => '', title => '', filename => '' }) if !@pod_source || !$pod_source[0];

            $self->debug('101: ' . substr join( "", map{ $_->{pod} }@pod_source ), 0, 50 );

            push @pods, @pod_source;
        }

        $config->{target}->{source} = \@pods;

        # deploy the project
        $self->debug('200: ' . $config->{target}->{type} );
        my $target = EPublisher::Target->new( $config->{target} );
        $target->publisher( $self );
        $target->deploy;
    }
}

sub _debug{
   my ($self,$ref) = @_;

   if( @_ == 2 and ref($ref) eq 'CODE' ){
      $self->{__debug} = $ref;
      $self->{DEBUG}   = 1;
   }

   return $self->{__debug};
}

sub debug {
    my ($self,$message) = @_;

    return if !$self->{DEBUG};
    $self->{__debug}->($message);
}

sub _config{
    my ($self,$bool,$data) = @_;

    if ( $bool and $data ) {
        $self->{__config} = $data;
    }
    elsif( !$self->{__config} or $bool ){
        unless( $self->config ){
            croak "no config file given!";
        }
        $self->{__config} = EPublisher::Config->get_config( $self->config );
    }

    return $self->{__config};
}

1;

__END__