File Coverage

blib/lib/EBook/MOBI/Driver/Example.pm

Criterion	Covered	Total	%
statement	24	28	85.7
branch	8	10	80.0
condition			n/a
subroutine	3	4	75.0
pod	2	2	100.0
total	37	44	84.0

package EBook::MOBI::Driver::Example;

our $VERSION = '0.72'; # TRIAL VERSION (hook for Dist::Zilla::Plugin::OurPkgVersion)

use EBook::MOBI::Converter;
use EBook::MOBI::Driver;

our @ISA = ('EBook::MOBI::Driver');

sub parse {
    my ($self, $input) = @_;

    # This module can help me to translate my stuff to html understood by
    # the mopipocket format
    my $converter = EBook::MOBI::Converter->new();

    # Because of "KISS" the module does not do much, but return the
    # converted stuff. So I need to manage the output myself.
    # I'll keep everything in this variable.
    my $mobiFormat = '';

    # We have some usefull methods from EBook::MOBI::Driver
    $self->debug_msg("Start parsing...");

    ########################################################################
    # Here is the parsing... for sure this looks different for any other   #
    # format. You might even use an existing parser like e.g. POD::Parser. #
    ########################################################################

    # work on each line, including newline
    while($input =~ /([^\n]+\n?)/g){
        my $line = $1;

        # this converts every html special char to it's html entity.
        # if your markups format does interfere with html special chars
        # you should call this AFTER parsing.
        my $mobi_line .= $converter->text($line);

        if ($mobi_line =~ /^!(.)!\s+(.*)/) {
            my $cmd = $1;
            my $txt = $2;

            $self->debug_msg('work');

            if ($cmd eq 'h')    { $mobiFormat .= $converter->title ($txt)  }
            elsif ($cmd eq 'i') { $mobiFormat .= $converter->italic($txt)
                                         .  $converter->newline();    }
            elsif ($cmd eq 'b') { $mobiFormat .= $converter->bold  ($txt)
                                         .  $converter->newline();    }
            elsif ($cmd eq ' ') { $mobiFormat .=                    $txt
                                         .  $converter->newline();    }
            else                { $self->debug_msg("Unknown format: $cmd") }
        }
        else {
            $self->debug_msg("Unknown line: $mobi_line");
        }
    }

    $self->debug_msg("...done");

    # and return the complete converted text
    return $mobiFormat;
}

sub set_options {
    my $self = shift;
    $self->debug_msg('this plugin has no options');
}

1;

__END__