File Coverage

lib/Digest/Perl/MD5.pm

Criterion	Covered	Total	%
statement	176	179	98.3
branch	14	18	77.7
condition	3	9	33.3
subroutine	22	23	95.6
pod	0	17	0.0
total	215	246	87.4

package Digest::Perl::MD5;
use strict;
use integer;
use Exporter;
use vars qw($VERSION @ISA @EXPORTER @EXPORT_OK);

@EXPORT_OK = qw(md5 md5_hex md5_base64);

@ISA     = 'Exporter';
$VERSION = '1.91';

# I-Vektor
sub A() { 0x67_45_23_01 }
sub B() { 0xef_cd_ab_89 }
sub C() { 0x98_ba_dc_fe }
sub D() { 0x10_32_54_76 }

# for internal use
sub MAX() { 0xFFFFFFFF }

# pad a message to a multiple of 64
sub padding {
    my $l = length( my $msg = shift() . chr(128) );
    $msg .= "\0" x ( ( $l % 64 <= 56 ? 56 : 120 ) - $l % 64 );
    $l = ( $l - 1 ) * 8;
    $msg .= pack 'VV', $l & MAX, ( $l >> 16 >> 16 );
}

sub rotate_left($$) {

    #$_[0] << $_[1] | $_[0] >> (32 - $_[1]);
    #my $right = $_[0] >> (32 - $_[1]);
    #my $rmask = (1 << $_[1]) - 1;
    ( $_[0] << $_[1] ) |
      ( ( $_[0] >> ( 32 - $_[1] ) ) & ( ( 1 << $_[1] ) - 1 ) );

    #$_[0] << $_[1] | (($_[0]>> (32 - $_[1])) & (1 << (32 - $_[1])) - 1);
}

sub gen_code {

    # Discard upper 32 bits on 64 bit archs.
    my $MSK = ( ( 1 << 16 ) << 16 ) ? ' & ' . MAX : '';

    #	FF => "X0=rotate_left(((X1&X2)|(~X1&X3))+X0+X4+X6$MSK,X5)+X1$MSK;",
    #	GG => "X0=rotate_left(((X1&X3)|(X2&(~X3)))+X0+X4+X6$MSK,X5)+X1$MSK;",
    # Only mask before rotate, not after; final mask in round() return
    my %f = (
        FF => "X0=rotate_left((X3^(X1&(X2^X3)))+X0+X4+X6$MSK,X5)+X1;",
        GG => "X0=rotate_left((X2^(X3&(X1^X2)))+X0+X4+X6$MSK,X5)+X1;",
        HH => "X0=rotate_left((X1^X2^X3)+X0+X4+X6$MSK,X5)+X1;",
        II => "X0=rotate_left((X2^(X1|(~X3)))+X0+X4+X6$MSK,X5)+X1;",
    );

    #unless ( (1 << 16) << 16) { %f = %{$CODES{'32bit'}} }
    #else { %f = %{$CODES{'64bit'}} }

    my %s = (    # shift lengths
        S11 => 7,
        S12 => 12,
        S13 => 17,
        S14 => 22,
        S21 => 5,
        S22 => 9,
        S23 => 14,
        S24 => 20,
        S31 => 4,
        S32 => 11,
        S33 => 16,
        S34 => 23,
        S41 => 6,
        S42 => 10,
        S43 => 15,
        S44 => 21
    );

    my $insert = "\n";
    while ( defined( my $data =  ) ) {
        chomp $data;
        next unless $data =~ /^[FGHI]/;
        my ( $func, @x ) = split /,/, $data;
        my $c = $f{$func};
        $c =~ s/X(\d)/$x[$1]/g;
        $c =~ s/(S\d{2})/$s{$1}/;
        $c =~ s/^(.*)=rotate_left\((.*),(.*)\)\+(.*)$//;

        my $su = 32 - $3;
        my $sh = ( 1 << $3 ) - 1;

        $c = "$1=(((\$r=$2)<<$3)|((\$r>>$su)&$sh))+$4";

        #my $rotate = "(($2 << $3) || (($2 >> (32 - $3)) & (1 << $2) - 1)))";
        # $c = "\$r = $2;
        # $1 = ((\$r << $3) | ((\$r >> (32 - $3))  & ((1 << $3) - 1))) + $4";
        $insert .= "\t$c\n";
    }
    close DATA;

    my $dump = '
  sub round {
	my ($a,$b,$c,$d) = @_[0 .. 3];
	my $r;' . $insert . '
	($_[0]+$a)'
      . $MSK
      . ', ($_[1]+$b)'
      . $MSK
      . ', ($_[2]+$c)'
      . $MSK
      . ', ($_[3]+$d)'
      . $MSK . ';
  }';
    eval $dump;

    # print "$dump\n";
    # exit 0;
}

gen_code();

#########################################
# Private output converter functions:
sub _encode_hex { unpack 'H*', $_[0] }

sub _encode_base64 {
    my $res;
    while ( $_[0] =~ /(.{1,45})/gs ) {
        $res .= substr pack( 'u', $1 ), 1;
        chop $res;
    }
    $res =~ tr|` -_|AA-Za-z0-9+/|;    #`
    chop $res;
    chop $res;
    $res;
}

#########################################
# OOP interface:
sub new {
    my $proto = shift;
    my $class = ref $proto || $proto;
    my $self  = {};
    bless $self, $class;
    $self->reset();
    $self;
}

sub reset {
    my $self = shift;
    delete $self->{_data};
    $self->{_state}  = [ A, B, C, D ];
    $self->{_length} = 0;
    $self;
}

sub add {
    my $self = shift;
    $self->{_data} .= join '', @_ if @_;
    my ( $i, $c );
    for $i ( 0 .. ( length $self->{_data} ) / 64 - 1 ) {
        my @X = unpack 'V16', substr $self->{_data}, $i * 64, 64;
        @{ $self->{_state} } = round( @{ $self->{_state} }, @X );
        ++$c;
    }
    if ($c) {
        substr( $self->{_data}, 0, $c * 64 ) = '';
        $self->{_length} += $c * 64;
    }
    $self;
}

sub finalize {
    my $self = shift;
    $self->{_data} .= chr(128);
    my $l = $self->{_length} + length $self->{_data};
    $self->{_data} .= "\0" x ( ( $l % 64 <= 56 ? 56 : 120 ) - $l % 64 );
    $l = ( $l - 1 ) * 8;
    $self->{_data} .= pack 'VV', $l & MAX, ( $l >> 16 >> 16 );
    $self->add();
    $self;
}

sub addfile {
    my ( $self, $fh ) = @_;
    if ( !ref($fh) && ref( \$fh ) ne "GLOB" ) {
        require Symbol;
        $fh = Symbol::qualify( $fh, scalar caller );
    }

    # $self->{_data} .= do{local$/;<$fh>};
    my $read   = 0;
    my $buffer = '';
    $self->add($buffer) while $read = read $fh, $buffer, 8192;
    die __PACKAGE__, " read failed: $!" unless defined $read;
    $self;
}

sub add_bits {
    my $self = shift;
    return $self->add( pack 'B*', shift ) if @_ == 1;
    my ( $b, $n ) = @_;
    die __PACKAGE__, " Invalid number of bits\n" if $n % 8;
    $self->add( substr $b, 0, $n / 8 );
}

sub digest {
    my $self = shift;
    $self->finalize();
    my $res = pack 'V4', @{ $self->{_state} };
    $self->reset();
    $res;
}

sub hexdigest {
    _encode_hex( $_[0]->digest );
}

sub b64digest {
    _encode_base64( $_[0]->digest );
}

sub clone {
    my $self  = shift;
    my $clone = {
        _state  => [ @{ $self->{_state} } ],
        _length => $self->{_length},
        _data   => $self->{_data}
    };
    bless $clone, ref $self || $self;
}

#########################################
# Procedural interface:
sub md5 {
    my $message = padding( join '', @_ );
    my ( $a, $b, $c, $d ) = ( A, B, C, D );
    my $i;
    for $i ( 0 .. ( length $message ) / 64 - 1 ) {
        my @X = unpack 'V16', substr $message, $i * 64, 64;
        ( $a, $b, $c, $d ) = round( $a, $b, $c, $d, @X );
    }
    pack 'V4', $a, $b, $c, $d;
}
sub md5_hex    { _encode_hex &md5 }
sub md5_base64 { _encode_base64 &md5 }

1;

=head1 NAME

Digest::MD5::Perl - Perl implementation of Ron Rivest's MD5 Algorithm

=head1 DISCLAIMER

This is B an interface (like C) but a Perl implementation of MD5.
It is written in perl only and because of this it is slow but it works without C-Code.
You should use C instead of this module if it is available.
This module is only useful for

=over 4

=item

computers where you cannot install C (e.g. lack of a C-Compiler)

=item

hashing only small amounts of data (less than one million bytes). I use it to
hash passwords.

=item

educational purposes

=back

=head1 SYNOPSIS

 # Functional style
 use Digest::MD5  qw(md5 md5_hex md5_base64);

 $hash = md5 $data;
 $hash = md5_hex $data;
 $hash = md5_base64 $data;


 # OO style
 use Digest::MD5;

 $ctx = Digest::MD5->new;

 $ctx->add($data);
 $ctx->addfile(*FILE);

 $digest = $ctx->digest;
 $digest = $ctx->hexdigest;
 $digest = $ctx->b64digest;

=head1 DESCRIPTION

This module has the same interface as the much faster C. So you can
easily exchange them, e.g.

	BEGIN {
	  eval {
	    require Digest::MD5;
	    import Digest::MD5 'md5_hex'
	  };
	  if ($@) { # oops, no Digest::MD5
	    require Digest::Perl::MD5;
	    import Digest::Perl::MD5 'md5_hex'
	  }
	}

If the C module is available it is used and if not you take
C.

You can also install the Perl part of Digest::MD5 together with Digest::Perl::MD5
and use Digest::MD5 as normal, it falls back to Digest::Perl::MD5 if it
cannot load its object files.

For detailed documentation see the C module.

=head1 EXAMPLES

The simplest way to use this library is to import the md5_hex()
function (or one of its cousins):

    use Digest::Perl::MD5 'md5_hex';
    print 'Digest is ', md5_hex('foobarbaz'), "\n";

The above example would print out the message

    Digest is 6df23dc03f9b54cc38a0fc1483df6e21

provided that the implementation is working correctly.  The same
checksum can also be calculated in OO style:

    use Digest::MD5;

    $md5 = Digest::MD5->new;
    $md5->add('foo', 'bar');
    $md5->add('baz');
    $digest = $md5->hexdigest;

    print "Digest is $digest\n";

The digest methods are destructive. That means you can only call them
once and the $md5 object is reset after use. You can make a copy with clone:

	$md5->clone->hexdigest

=head1 LIMITATIONS

This implementation of the MD5 algorithm has some limitations:

=over 4

=item

It's slow, very slow. I've done my very best but Digest::MD5 is still about 100 times faster.
You can only hash data up to one million bytes in an acceptable time. But it's very useful
for hashing small amounts of data like passwords.

=item

You can only hash up to 2^32 bits = 512 MB on 32-bit archs. But you should
use C for those amounts of data anyway.

=back

=head1 SEE ALSO

L

L

RFC 1321

tools/md5: a small BSD compatible md5 tool written in pure perl.

=head1 COPYRIGHT

This library is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

 Copyright 2000 Christian Lackas, Imperia Software Solutions
 Copyright 1998-1999 Gisle Aas.
 Copyright 1995-1996 Neil Winton.
 Copyright 1991-1992 RSA Data Security, Inc.

The MD5 algorithm is defined in RFC 1321. The basic C code
implementing the algorithm is derived from that in the RFC and is
covered by the following copyright:

=over 4

=item

Copyright (C) 1991-1992, RSA Data Security, Inc. Created 1991. All
rights reserved.

License to copy and use this software is granted provided that it
is identified as the "RSA Data Security, Inc. MD5 Message-Digest
Algorithm" in all material mentioning or referencing this software
or this function.

License is also granted to make and use derivative works provided
that such works are identified as "derived from the RSA Data
Security, Inc. MD5 Message-Digest Algorithm" in all material
mentioning or referencing the derived work.

RSA Data Security, Inc. makes no representations concerning either
the merchantability of this software or the suitability of this
software for any particular purpose. It is provided "as is"
without express or implied warranty of any kind.

These notices must be retained in any copies of any part of this
documentation and/or software.

=back

This copyright does not prohibit distribution of any version of Perl
containing this extension under the terms of the GNU or Artistic
licenses.

=head1 AUTHORS

The original MD5 interface was written by Neil Winton
().

C was made by Gisle Aas  (I took his Interface
and part of the documentation).

Thanks to Guido Flohr for his 'use integer'-hint.

This release was made by Christian Lackas .

=cut

__DATA__