File Coverage

blib/lib/Digest/ED2K.pm

Criterion	Covered	Total	%
statement	45	45	100.0
branch	8	10	80.0
condition	3	6	50.0
subroutine	13	13	100.0
pod	7	7	100.0
total	76	81	93.8

package Digest::ED2K;
use common::sense;
use Digest::MD4 ();
use Exporter 'import';
our @EXPORT_OK = qw(ed2k ed2k_hex ed2k_base64);

use Digest::base 1.03;
BEGIN { push @Digest::ED2K::ISA, 'Digest::base' }

use version 0.077; our $VERSION = version->declare('v1.1.1');

sub CHUNK_SIZE() { 9728000 }

sub new {
	my $class = shift;
	bless { chunk_ctx => Digest::MD4->new }, ref $class || $class;
}

sub clone {
	my $self = shift;
	bless {
		($self->{ctx} ? (ctx => $self->{ctx}->clone) : ()),
		chunk_ctx    => $self->{chunk_ctx}->clone,
		chunk_length => $self->{chunk_length},
	}, ref $self;
}

sub add {
	return shift->add(join '', @_) if @_ > 2;

	my $self = shift;

	# Adding buffer won't cross chunk border.
	# Avoid copying.
	if (CHUNK_SIZE - $self->{chunk_length} > length $_[0]) {
		$self->{chunk_ctx}->add($_[0]);
		$self->{chunk_length} += length $_[0];

		return $self;
	}

	# Buffer intersects chunk border, copy for modification.
	my $buffer = shift;

	while ($buffer) {
		my $need_length = CHUNK_SIZE - $self->{chunk_length};

		my $substr = substr $buffer, 0, $need_length;
		$self->{chunk_ctx}->add($substr);
		$self->{chunk_length} += length $substr;

		# Completed chunk
		if ($self->{chunk_length} == CHUNK_SIZE) {
			my $ctx = $self->{ctx} ||= Digest::MD4->new;

			$ctx->add($self->{chunk_ctx}->digest);
			$self->{chunk_length} = 0;
		}

		$buffer = substr $buffer, $need_length;
	}

	return $self;
}

sub digest {
	my $self = shift;
	my ($ctx) = delete @$self{qw( ctx chunk_length )};

	# One chunk
	return $self->{chunk_ctx}->digest unless $ctx;

	# Multi chunk
	$ctx->add($self->{chunk_ctx}->digest)->digest;
}

sub ed2k(@) {
	Digest::ED2K->new->add(@_)->digest;
}

sub ed2k_hex(@) {
	Digest::ED2K->new->add(@_)->hexdigest;
}

sub ed2k_base64(@) {
	Digest::ED2K->new->add(@_)->b64digest;
}

0x6B63;
__END__