File Coverage

lib/Die/Hard.pm

Criterion	Covered	Total	%
statement	45	61	73.7
branch	13	26	50.0
condition	2	6	33.3
subroutine	12	14	85.7
pod	4	4	100.0
total	76	111	68.4

package Die::Hard;

use 5.008;
use Moo;
use Scalar::Util ();
use Carp ();
use if $] < 5.010, 'UNIVERSAL::DOES';

BEGIN {
	no warnings;
	$Die::Hard::AUTHORITY = 'cpan:TOBYINK';
	$Die::Hard::VERSION   = '0.002';
}

has proxy_for => (
	is       => 'ro',
	isa      => sub {
		Scalar::Util::blessed($_[0])
			or Carp::confess("proxy_for must be a blessed object")
	},
	required => 1,
);

has last_error => (
	is       => 'ro',
	required => 0,
	writer   => '_set_last_error',
	clearer  => '_clear_last_error',
);

sub BUILDARGS
{
	my $class = shift;
	return +{ proxy_for => $_[0] } if @_ == 1 && Scalar::Util::blessed($_[0]);
	return $class->SUPER::BUILDARGS(@_);
}

sub AUTOLOAD
{
	my ($meth) = (our $AUTOLOAD =~ /::([^:]+)$/);

	local $@ = undef;
	my $self = shift;

	$self->_clear_last_error;

	my $coderef = $self->proxy_for->can($meth) || $meth;

	if (wantarray)
	{
		my @r;
		$self->_set_last_error($@)
			unless eval { @r = $self->proxy_for->$coderef(@_); 1 };
		return @r;
	}
	elsif (defined wantarray)
	{
		my $r;
		$self->_set_last_error($@)
			unless eval { $r = $self->proxy_for->$coderef(@_); 1 };
		return $r;
	}
	else
	{
		$self->_set_last_error($@)
			unless eval { $self->proxy_for->$coderef(@_); 1 };
		return;
	}
}

sub can
{
	my ($self, $method) = @_;
	return $self->SUPER::can($method) unless Scalar::Util::blessed($self);

	my $i_can  = $self->SUPER::can($method);
	my $he_can = $self->proxy_for->can($method);

	return $i_can if $i_can;
	return sub { our $AUTOLOAD = $method; goto \&AUTOLOAD } if $he_can;
	return;
}

sub DOES
{
	my ($self, $role) = @_;
	return $self->SUPER::DOES($role) unless Scalar::Util::blessed($self);
	$self->SUPER::DOES($role) or $self->proxy_for->DOES($role);
}

sub isa
{
	my ($self, $role) = @_;
	return $self->SUPER::isa($role) unless Scalar::Util::blessed($self);
	$self->SUPER::isa($role) or $self->proxy_for->isa($role);
}

no Moo;

1;
__END__