File Coverage

blib/lib/Device/RFXCOM/Encoder/HomeEasy.pm

Criterion	Covered	Total	%
statement	54	58	93.1
branch	12	14	85.7
condition	2	6	33.3
subroutine	9	9	100.0
pod	2	2	100.0
total	79	89	88.7

use strict;
use warnings;
package Device::RFXCOM::Encoder::HomeEasy;
$Device::RFXCOM::Encoder::HomeEasy::VERSION = '1.163170';
# ABSTRACT: Device::RFXCOM::Encoder::HomeEasy encode HomeEasy RF messages


use 5.006;
use constant DEBUG => $ENV{DEVICE_RFXCOM_ENCODER_HOMEEASY_DEBUG};
use Carp qw/croak carp/;
use base 'Device::RFXCOM::Encoder';
use Device::RFXCOM::Response::HomeEasy;


sub encode {
  my ($self, $parent, $p) = @_;
  my @bytes = ( 0, 0, 0, 0, 0 );
  my $length = 33;
  my $command;

  unless (exists $p->{command} && exists $p->{unit} && exists $p->{address}) {
    carp $self.'->encode: Invalid homeeasy message';
    return [];
  }
  if ($p->{command} eq 'preset') {
    unless (exists $p->{level}) {
      carp $self.'->encode: Invalid homeeasy message';
      return [];
    }
    $length = 36;
    $bytes[4] = $p->{level} << 4;
    $command = 0;
  } else {
    $command = $p->{command} eq 'on' ? 1 : 0;
  }
  if ($p->{unit} eq 'group') {
    $p->{unit} = 0;
    $command |= 0x2;
  }
  my $addr = encode_address($p->{address});
  $bytes[0] = $addr >> 18;
  $bytes[1] = ($addr >> 10) & 0xff;
  $bytes[2] = ($addr >> 2) & 0xff;
  $bytes[3] = (($addr & 0x3) << 6);
  $bytes[3] |= $p->{unit};
  $bytes[3] |= ($command << 4);
  return {
          raw => (pack 'C6', $length, @bytes),
          desc =>
            'homeeasy: '.(join '/',
                          grep { defined $_
                               } @{$p}{qw/command address unit/})
         },
}


sub encode_address {
  my $addr = shift;
  return hex($addr) & 0x3ffffff if ($addr =~ /^0x[0-9a-f]{1,8}$/i);
  my $val = 0;
  my $offset = 0;
  foreach my $b (map { ord $_ } split //, $addr) {
    $val ^= ($b&0x7f) << $offset;
    $offset += 4;
    $offset = 0 if ($offset > 20);
  }
  return $val & 0x3ffffff;
}

1;

__END__