| 1 | # $Id: /local/datetime/modules/DateTime-Event-Lunar/trunk/lib/DateTime/Event/Lunar.pm 11665 2007-05-27T15:50:16.141243Z daisuke $ | ||
| 2 | # | ||
| 3 | # Copyright (c) 2004-2007 Daisuke Maki <daisuke@endeworks.jp> | ||
| 4 | # All rights reserved. | ||
| 5 | |||
| 6 | package DateTime::Event::Lunar; | ||
| 7 | use strict; | ||
| 8 | use vars qw($VERSION @ISA %EXPORT_TAGS); | ||
| 9 | use DateTime; | ||
| 10 | use DateTime::Set; | ||
| 11 | use DateTime::Util::Calc qw( | ||
| 12 | min max search_next moment dt_from_moment mod binary_search | ||
| 13 | ); | ||
| 14 | use DateTime::Util::Astro::Moon qw(MEAN_SYNODIC_MONTH); | ||
| 15 | use Exporter; | ||
| 16 | use Math::Round qw(round); | ||
| 17 | BEGIN { | ||
| 18 | $VERSION = '0.06'; | ||
| 19 | @ISA = qw(Exporter); | ||
| 20 | %EXPORT_TAGS = ( | ||
| 21 | phases => [ qw(NEW_MOON FIRST_QUARTER FULL_MOON LAST_QUARTER) ] | ||
| 22 | ); | ||
| 23 | Exporter::export_ok_tags('phases'); | ||
| 24 | } | ||
| 25 | use constant NEW_MOON => 0; | ||
| 26 | use constant FIRST_QUARTER => 90; | ||
| 27 | use constant FULL_MOON => 180; | ||
| 28 | use constant LAST_QUARTER => 270; | ||
| 29 | use constant ZEROTH_NEW_MOON => DateTime::Util::Astro::Moon::nth_new_moon(0); | ||
| 30 | |||
| 31 | sub _new | ||
| 32 | { | ||
| 33 | my $class = shift; | ||
| 34 | return bless {}, $class; | ||
| 35 | } | ||
| 36 | |||
| 37 | sub new_moon | ||
| 38 | { | ||
| 39 | my $class = shift; | ||
| 40 | my $self = $class->_new(@_); | ||
| 41 | return DateTime::Set->from_recurrence( | ||
| 42 | next => sub { | ||
| 43 | return $_[0] if $_[0]->is_infinite; | ||
| 44 | $self->new_moon_after( datetime => $_[0] ) }, | ||
| 45 | previous => sub { | ||
| 46 | return $_[0] if $_[0]->is_infinite; | ||
| 47 | $self->new_moon_before( datetime => $_[0] ) } | ||
| 48 | ); | ||
| 49 | } | ||
| 50 | |||
| 51 | sub lunar_phase | ||
| 52 | { | ||
| 53 | my $class = shift; | ||
| 54 | my $self = $class->_new(); | ||
| 55 | my %args = @_; | ||
| 56 | |||
| 57 | my $phase = $args{phase}; | ||
| 58 | return DateTime::Set->from_recurrence( | ||
| 59 | next => sub { | ||
| 60 | return $_[0] if $_[0]->is_infinite; | ||
| 61 | $self->lunar_phase_after( | ||
| 62 | datetime => $_[0], | ||
| 63 | phase => $phase, | ||
| 64 | ) | ||
| 65 | }, | ||
| 66 | previous => sub { | ||
| 67 | return $_[0] if $_[0]->is_infinite; | ||
| 68 | $self->lunar_phase_before( | ||
| 69 | datetime => $_[0], | ||
| 70 | phase => $phase, | ||
| 71 | ) | ||
| 72 | } | ||
| 73 | ); | ||
| 74 | } | ||
| 75 | |||
| 76 | # [1] p.190 | ||
| 77 | sub new_moon_before | ||
| 78 | { | ||
| 79 | my $self = shift; | ||
| 80 | my %args = @_; # datetime => $dt, on_or_before => $boolean | ||
| 81 | my $dt = $args{datetime}; | ||
| 82 | return $dt if $dt->is_infinite; | ||
| 83 | |||
| 84 | my $phi = DateTime::Util::Astro::Moon::lunar_phase($dt); | ||
| 85 | my $n = round( (moment($dt) - moment(ZEROTH_NEW_MOON)) / | ||
| 86 | MEAN_SYNODIC_MONTH - $phi / 360 ); | ||
| 87 | |||
| 88 | my $nm_index = search_next( | ||
| 89 | base => $n, | ||
| 90 | check => sub { | ||
| 91 | my $p = DateTime::Util::Astro::Moon::nth_new_moon($_[0]); | ||
| 92 | $args{on_or_before} ? $p <= $dt : $p < $dt | ||
| 93 | }, | ||
| 94 | next => sub { $_[0] - 1 } | ||
| 95 | ); | ||
| 96 | my $rv = DateTime::Util::Astro::Moon::nth_new_moon($nm_index); | ||
| 97 | $rv->set_time_zone($dt->time_zone); | ||
| 98 | return $rv; | ||
| 99 | } | ||
| 100 | |||
| 101 | # [1] p.190 | ||
| 102 | sub new_moon_after | ||
| 103 | { | ||
| 104 | my $self = shift; | ||
| 105 | my %args = @_; # datetime => $dt, on_or_after => $boolean | ||
| 106 | my $dt = $args{datetime}; | ||
| 107 | return $dt if $dt->is_infinite; | ||
| 108 | |||
| 109 | my $phi = DateTime::Util::Astro::Moon::lunar_phase($dt); | ||
| 110 | my $n = round( (moment($dt) - moment(ZEROTH_NEW_MOON)) / | ||
| 111 | MEAN_SYNODIC_MONTH - $phi / 360 ); | ||
| 112 | |||
| 113 | my $nm_index = search_next( | ||
| 114 | base => $n, | ||
| 115 | check => sub { | ||
| 116 | my $p = DateTime::Util::Astro::Moon::nth_new_moon($_[0]); | ||
| 117 | $args{on_or_after} ? $p >= $dt : $p > $dt }, | ||
| 118 | next => sub { $_[0] + 1 } | ||
| 119 | ); | ||
| 120 | my $rv = DateTime::Util::Astro::Moon::nth_new_moon($nm_index); | ||
| 121 | $rv->set_time_zone($dt->time_zone); | ||
| 122 | return $rv; | ||
| 123 | } | ||
| 124 | |||
| 125 | use constant LUNAR_PHASE_DELTA => 10 ** -5; | ||
| 126 | use constant MEAN_SYNODIC_MONTH_FRAG => | ||
| 127 | (Math::BigInt->bone() / 360) * MEAN_SYNODIC_MONTH; | ||
| 128 | |||
| 129 | # [1] p.192 | ||
| 130 | sub lunar_phase_before | ||
| 131 | { | ||
| 132 | my $self = shift; | ||
| 133 | my %args = @_; # datetime => $dt, phase => $phae | ||
| 134 | my($dt, $phi) = ($args{datetime}, $args{phase}); | ||
| 135 | return $dt if $dt->is_infinite; | ||
| 136 | |||
| 137 | my $dt_moment = moment($dt); | ||
| 138 | my $tau = $dt_moment - MEAN_SYNODIC_MONTH_FRAG * | ||
| 139 | mod(DateTime::Util::Astro::Moon::lunar_phase($dt) - $phi, 360); | ||
| 140 | my $l = $tau - 2; | ||
| 141 | my $u = min($dt_moment, $tau + 2); | ||
| 142 | |||
| 143 | my $moment = binary_search($l, $u, | ||
| 144 | sub { abs($_[0] - $_[1]) <= LUNAR_PHASE_DELTA }, | ||
| 145 | sub { mod(DateTime::Util::Astro::Moon::lunar_phase( | ||
| 146 | dt_from_moment($_[0])) - $phi, 360) < 180 } ); | ||
| 147 | my $rv = dt_from_moment($moment); | ||
| 148 | $rv->set_time_zone($dt->time_zone); | ||
| 149 | return $rv; | ||
| 150 | } | ||
| 151 | |||
| 152 | # [1] p.192 | ||
| 153 | sub lunar_phase_after | ||
| 154 | { | ||
| 155 | my $self = shift; | ||
| 156 | my %args = @_; # datetime => $dt, phase => $phase, on_or_after => $boolean | ||
| 157 | my($dt, $phi) = ($args{datetime}, $args{phase}); | ||
| 158 | |||
| 159 | my $current_phase = DateTime::Util::Astro::Moon::lunar_phase($dt); | ||
| 160 | return $dt if $dt->is_infinite; | ||
| 161 | |||
| 162 | my $dt_moment = moment($dt); | ||
| 163 | my $tau = | ||
| 164 | $dt_moment + MEAN_SYNODIC_MONTH_FRAG * | ||
| 165 | mod($phi - DateTime::Util::Astro::Moon::lunar_phase($dt), 360) | ||
| 166 | ; | ||
| 167 | my $l = max($dt_moment, $tau - 2); | ||
| 168 | my $u = $tau + 2; | ||
| 169 | |||
| 170 | my $rv_moment = binary_search($l, $u, | ||
| 171 | sub { abs($_[0] - $_[1]) <= LUNAR_PHASE_DELTA }, | ||
| 172 | sub { mod(DateTime::Util::Astro::Moon::lunar_phase( | ||
| 173 | dt_from_moment($_[0])) - $phi, 360) < 180 } ); | ||
| 174 | my $rv = dt_from_moment($rv_moment); | ||
| 175 | |||
| 176 | # if the delta is within some amount, we've probably just calculated | ||
| 177 | # the same date for the same lunar phase. In that case we just | ||
| 178 | # jump ahead 28 days (which is still safely before the next | ||
| 179 | # date/time for the given phase) and re-calculate | ||
| 180 | |||
| 181 | if ($args{on_or_after}) { | ||
| 182 | my $delta = $rv->delta_ms($dt); | ||
| 183 | if (abs($delta->delta_minutes()) < 60) { | ||
| 184 | $rv = $self->lunar_phase_after( | ||
| 185 | datetime => $dt + DateTime::Duration->new(days => 28), | ||
| 186 | phase => $phi | ||
| 187 | ); | ||
| 188 | } | ||
| 189 | } | ||
| 190 | |||
| 191 | $rv->set_time_zone($dt->time_zone); | ||
| 192 | return $rv; | ||
| 193 | } | ||
| 194 | |||
| 195 | 1; | ||
| 196 | |||
| 197 | __END__ |