File Coverage

blib/lib/Date/Holidays/PL.pm

Criterion	Covered	Total	%
statement	68	68	100.0
branch	4	4	100.0
condition			n/a
subroutine	18	18	100.0
pod	4	4	100.0
total	94	94	100.0

package Date::Holidays::PL;
BEGIN {
  $Date::Holidays::PL::AUTHORITY = 'cpan:AJGB';
}
BEGIN {
  $Date::Holidays::PL::VERSION = '1.110050';
}
# ABSTRACT: Determine holidays for Poland

use strict;
use warnings;
use utf8;

use parent qw( Date::Holidays::Abstract );

use DateTime;
use Params::Validate qw( validate validate_pos SCALAR BOOLEAN OBJECT );
use Date::Easter qw( gregorian_easter );
use Try::Tiny;

use Sub::Exporter -setup => {
    exports => [
        qw( pl_holidays is_pl_holiday pl_holidays_dt is_pl_holiday_dt ),
    ],
};


# holidays always present
my %SharedHolidays = map {
    $_ => 1
} qw( 0101 0501 1101 1225 1226 );

# law changes in 1951, 1960, 1989, 1990 and 2011
my %ChangesByYear = (
    (
        map {
            $_ => {
                %SharedHolidays,
                map { $_ => 1 } qw( 0106 0722 0815 )
            }
        } (1951 .. 1959),
    ),
    (
        map {
            $_ => {
                %SharedHolidays,
                map { $_ => 1 } qw( 0722 )
            }
        } (1960 .. 1988),
    ),
    1989 => {
        %SharedHolidays,
        map { $_ => 1 } qw( 0722 0815 1111 )
    },
    # since 1990
    1990 => {
        %SharedHolidays,
        map { $_ => 1 } qw( 0503 0815 1111 )
    },
    # since 2011
    'CURRENT' => {
        %SharedHolidays,
        map { $_ => 1 } qw( 0106 0503 0815 1111 )
    },
);
# always on those dates
my %FixedHolidays = (
    # New Year's Day
    '0101' => 'Nowy Rok',
    # Epiphany (1951-1959 only)
    '0106' => 'Trzech Króli',
    # Labor Day
    '0501' => 'Święto Państwowe',
    # Constitution Day ( since 1990 )
    '0503' => 'Święto Narodowe Trzeciego Maja',
    # Polish Committee of National Liberation Manifesto (1951-1989 only)
    '0722' => 'Święto Odrodzenia Polski',
    # Assumption of the Blessed Virgin Mary ( 1951-1959, 1989+ )
    '0815' => 'Wniebowzięcie Najświętszej Maryi Panny',
    # All Saints' Day
    '1101' => 'Wszystkich Świętych',
    # Independence Day ( since 1989 )
    '1111' => 'Narodowe Święto Niepodległości',
    # Christmas Day
    '1225' => 'pierwszy dzień Bożego Narodzenia',
    # Boxing Day
    '1226' => 'drugi dzień Bożego Narodzenia',
);

# Params::Validate config
my $ValidateOpts = {
    year => {
        type => SCALAR,
        regex => qr/^\d{4}$/,
        callbacks => {
            'between 1951 and 9999' => sub {
                shift >= 1951
            },
        },
    },
    month => {
        type => SCALAR,
    },
    day => {
        type => SCALAR,
    },
    WEEKENDS => {
        type => BOOLEAN,
        default => 1,
        optional => 1,
    }
};


sub pl_holidays {
    my ($year) = validate_pos(@{[shift]},
        $ValidateOpts->{year},
    );
    my %args = validate(@_,
        {
            WEEKENDS => $ValidateOpts->{WEEKENDS},
        }
    );

    my $y = exists $ChangesByYear{$year} ? $year : 'CURRENT';

    my $holidays = {
        _compute_movablefeasts_for_year( $year ),
        map {
            $_ => $FixedHolidays{$_}
        } keys %{ $ChangesByYear{$y} },
    };

    unless ( $args{WEEKENDS} ) {
        my @weekend_holidays = grep {
                my ($m, $d) = unpack "A2A2", $_;

                my $dt = DateTime->new(
                    year => $year,
                    month => $m,
                    day => $d
                );

                $dt->day_of_week >= 6;
            } keys %$holidays;

        delete @{$holidays}{ @weekend_holidays };
    }

    return $holidays;
};


sub pl_holidays_dt {
    my $year = shift;
    my $holidays = pl_holidays($year, @_);

    return +{
        map {
            my ($m, $d) = unpack "A2A2", $_;
            my $name = $holidays->{$_};

            $name => DateTime->new(
                year => $year,
                month => $m,
                day => $d
            );
        } keys %$holidays
    }
}


sub is_pl_holiday {
    my ($year, $month, $day) = validate_pos(@_,
        @{$ValidateOpts}{qw(year month day)}
    );

    my $dt;

    # let DateTime validate the date - no need to validate twice
    try {
        $dt = DateTime->new(
            year => $year,
            month => $month,
            day => $day,
        );
    } catch {
        die "Date $year-$month-$day is invalid: $_";
    };

    my $holidays = pl_holidays( $year );

    my $md = $dt->strftime('%m%d');
    return $holidays->{$md};
}


sub is_pl_holiday_dt {
    my ($dt) = validate_pos(@_,
        {
            type => OBJECT,
            isa => 'DateTime',
        }
    );

    my $holidays = pl_holidays( $dt->year );

    my $md = $dt->strftime('%m%d');
    return $holidays->{$md};
}

# calculate moveable feast for given year
sub _compute_movablefeasts_for_year {
    my $year = shift;

    # already calculated

    my @easter_md = map { sprintf('%02d', $_ ) } gregorian_easter( $year );

    my $easter = DateTime->new(
        year => $year,
        month => $easter_md[0],
        day => $easter_md[1],
    );

    return (
        # Easter Sunday
        $easter->strftime('%m%d') =>
            'pierwszy dzień Wielkanocy',
        # Easter Monday
        $easter->clone->add( days => 1)->strftime('%m%d') =>
            'drugi dzień Wielkanocy',
        # Pentecoste Sunday
        $easter->clone->add( days => 49)->strftime('%m%d') =>
            'pierwszy dzień Zielonych Świątek',
        # Corpus Christi
        $easter->clone->add( days => 60)->strftime('%m%d') =>
            'dzień Bożego Ciała',
    );
}




1;

__END__