File Coverage

blib/lib/Date/Holidays/KR.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch	20	28	71.4
condition	5	6	83.3
subroutine	13	13	100.0
pod	2	4	50.0
total	97	108	89.8

package Date::Holidays::KR;
use strict;
use warnings;
use base 'Exporter';
use Date::Korean;
use DateTime;
use Try::Tiny;
our $VERSION = '0.05';

our @EXPORT = qw/is_holiday holidays/;
our @EXPORT_OK = qw/is_solar_holiday is_lunar_holiday/;

my $SOLAR = {
    '0101' => '신정',
    '0301' => '삼일절',
    '0505' => '어린이날',
    '0606' => '현충일',
    '0815' => '광복절',
    '1003' => '개천절',
    '1225' => '크리스마스',
};

my $LUNAR = {
    '1229' => '설앞날',
    '1230' => '설앞날',
    '0101' => '설날',
    '0102' => '설뒷날',
    '0408' => '부처님오신날',
    '0814' => '추석앞날',
    '0815' => '추석',
    '0816' => '추석뒷날',
};

sub is_solar_holiday {
    my ($year, $month, $day) = @_;
    defined $year  || return;
    defined $month || return;
    defined $day   || return;
    return $SOLAR->{sprintf '%02d%02d', $month, $day};
}

sub is_lunar_holiday {
    my ($year, $month, $day) = @_;
    defined $year  || return;
    defined $month || return;
    defined $day   || return;

    my ($ly, $lm, $ld, $leap) = sol2lun($year, $month, $day);

    my $flag = _check_korean_new_year($year, $lm, $ld, $month, $day);
    return if $flag;
    return $LUNAR->{sprintf '%02d%02d', $lm, $ld};
}

sub is_holiday {
    is_solar_holiday(@_) || is_lunar_holiday(@_);
}

sub holidays {
    my ($year) = @_;
    defined $year || return;

    my $holidays = { %$SOLAR };

    for my $_year ( ($year - 1) .. $year ) {
        for my $date ( keys %$LUNAR ) {
            my ($lm, $ld) = $date =~ /^(\d\d)(\d\d)$/;

            $lm = int $lm;
            $ld = int $ld;

            my ( $y, $m, $d ) =
                try   { lun2sol($_year, $lm, $ld, 1) }
                catch {
                    try { lun2sol($_year, $lm, $ld, 0) }
                    catch { () };
                };

            next unless $y;
            next unless $y eq $year;

            #
            # check Korean New Year
            #
            my $flag = _check_korean_new_year($year, $lm, $ld, $m, $d);
            next if $flag;
            $holidays->{sprintf '%02d%02d', $m, $d} = $LUNAR->{$date};
        }
    }

    $holidays;
}

sub _check_korean_new_year {
    my ($y,$lm, $ld, $m, $d) = @_;

    if ( $lm == 12 && $ld == 29 ) {
        my $dt = DateTime->new(
            year      => $y,
            month     => $m,
            day       => $d,
        )->add( days => 1 );

        my ( $ly2, $lm2, $ld2 ) = sol2lun($dt->year, $dt->month, $dt->day);

        return 1 if $lm2 == 12 && $ld2 == 30;
    }
    return 0;
}

1;
__END__