File Coverage

blib/lib/Date/Easy/Date.pm

Criterion	Covered	Total	%
statement	78	79	98.7
branch	22	22	100.0
condition	4	6	66.6
subroutine	23	23	100.0
pod	10	10	100.0
total	137	140	97.8

package Date::Easy::Date;

use strict;
use warnings;
use autodie;

our $VERSION = '0.09_01'; # TRIAL VERSION

use Exporter;
use parent 'Exporter';
our @EXPORT_OK = qw< date today >;
our %EXPORT_TAGS = ( all => \@EXPORT_OK );

use parent 'Date::Easy::Datetime';

use Carp;
use Scalar::Util 'blessed';
use Time::Local 1.26, qw< timegm_modern >;


##############################
# FUNCTIONS (*NOT* METHODS!) #
##############################


sub date
{
	my $date = shift;
	if ( $date =~ /^-?\d+$/ )
	{
		if ($date < 29000000 and $date >= 10000000)
		{
			my @time = $date =~ /^(\d{4})(\d{2})(\d{2})$/;
			return Date::Easy::Date->new(@time);
		}
		return Date::Easy::Date->new($date);
	}
	elsif ( $date !~ /\d/ )
	{
		my $time = _parsedate($date);
		croak("Illegal date: $date") unless defined $time;
		return Date::Easy::Date->new($time);
	}
	else
	{
		my (undef,undef,undef, $d, $m, $y)								# ignore first 3 values (time portion)
			= Date::Easy::Datetime::_strptime($date, 'local');			# remember: parse as local, store as UTC
		if (defined $y)													# they're either all defined, or it's bogus
		{
			# return value from _strptime for month is still in the funky 0 - 11 range
			return Date::Easy::Date->new($y, $m + 1, $d);
		}
		else
		{
			my $time = _parsedate($date);
			croak("Illegal date: $date") unless defined $time;
			return Date::Easy::Date->new($time);
		}
	}
	die("reached unreachable code");
}

sub today () { Date::Easy::Date->new }


sub _parsedate
{
	require Time::ParseDate;
	my $string = shift;

	# Remove any timezone specifier so we get the date as it was in that timezone.
	# I've gathered up all timezone matching code from Time::ParseDate as of v2015.103.
																		# matching code from Time/ParseDate.pm:
	my $break = qr{(?:\s+|\Z|\b(?![-:.,/]\d))};												# line 67
	$string =~ s/
			(?:
					[+-] \d\d:?\d\d \s+ \( "? (?: [A-Z]{1,4}[TCW56] | IDLE ) \)				# lines 424-435
				|	GMT \s* [-+]\d{1,2}														# line 441
				|	(?: GMT \s* )? [+-] \d\d:?\d\d											# line 452
				|	"? (?: [A-Z]{1,4}[TCW56] | IDLE )										# line 457 (and 695-700)
			) $break //x;

	# We *must* force scalar context.  Remember, parsedate called in list context also returns the
	# "remainder" of the parsed string (which is often undef, which could wreak havoc with a call
	# that incorporates our return value, particularly one to _mktime).
	return scalar Time::ParseDate::parsedate($string, DATE_REQUIRED => 1);
}


#######################
# REGULAR CLASS STUFF #
#######################


sub new
{
	my $class = shift;
	my ($y, $m, $d);
	if (@_ == 3)
	{
		($y, $m, $d) = @_;
		--$m;										# timegm will expect month as 0..11
	}
	else
	{
		my ($time) = @_;
		$time = time unless defined $time;
		if (my $conv_class = blessed $time)
		{
			if ( $time->isa('Time::Piece') )
			{
				($d, $m, $y) = ($time->mday, $time->_mon, $time->year);
			}
			else
			{
				croak("Don't know how to convert $conv_class to $class");
			}
		}
		else
		{
			($d, $m, $y) = (localtime $time)[3..5];						# `Date`s are parsed relative to local time ...
			$y += 1900;			# (no 2-digit dates allowed!)
		}
	}

	my $truncated_date =
			eval { timegm_modern( 0,0,0, $d,$m,$y ) };					# ... but stored as UTC
	croak("Illegal date: $y/" . ($m + 1) . "/$d") unless defined $truncated_date;
	return $class->_mkdate($truncated_date);
}

sub _mkdate
{
	my ($invocant, $epoch) = @_;
	my $class = ref $invocant || $invocant;
	return bless Date::Easy::Datetime->new(UTC => $epoch), $class;		# always UTC
}


############################
# OVERRIDDEN FROM DATETIME #
############################


sub split
{
	my $impl = shift->{impl};
	( $impl->year, $impl->mon, $impl->mday )
}


# override addition and subtraction
# numbers added to a ::Date are days

sub _add_integer		{ $_[0]->add_days($_[1])      }
sub _subtract_integer	{ $_[0]->subtract_days($_[1]) }


# These are illegal to call.
sub add_seconds { die("cannot call add_seconds on a Date value") }
sub add_minutes { die("cannot call add_minutes on a Date value") }
sub add_hours { die("cannot call add_hours on a Date value") }
sub subtract_seconds { die("cannot call subtract_seconds on a Date value") }
sub subtract_minutes { die("cannot call subtract_minutes on a Date value") }
sub subtract_hours { die("cannot call subtract_hours on a Date value") }



1;



# ABSTRACT: easy date class
# COPYRIGHT

__END__