File Coverage

blib/lib/Data/XLSX/Parser.pm

Criterion	Covered	Total	%
statement	10	12	83.3
branch			n/a
condition			n/a
subroutine	4	4	100.0
pod			n/a
total	14	16	87.5

package Data::XLSX::Parser;
use strict;
use warnings;

our $VERSION = '0.14';

use Data::XLSX::Parser::DocumentArchive;
use Data::XLSX::Parser::Workbook;
use Data::XLSX::Parser::SharedStrings;
use Data::XLSX::Parser::Styles;
use Data::XLSX::Parser::Sheet;
use Data::XLSX::Parser::Relationships;

my $workbook_schema = 'http://schemas.openxmlformats.org/officeDocument/2006/relationships/worksheet';

sub new {
    my ($class) = @_;

    bless {
        _row_event_handler => [],
        _archive           => undef,
        _workbook          => undef,
        _shared_strings    => undef,
        _relationships    => undef,
    }, $class;
}

sub add_row_event_handler {
    my ($self, $handler) = @_;
    push @{ $self->{_row_event_handler} }, $handler;
}

sub open {
    my ($self, $file) = @_;
    $self->{_archive} = Data::XLSX::Parser::DocumentArchive->new($file);
}

sub workbook {
    my ($self) = @_;
    $self->{_workbook} ||= Data::XLSX::Parser::Workbook->new($self->{_archive});
}

sub shared_strings {
    my ($self) = @_;
    $self->{_shared_strings} ||= Data::XLSX::Parser::SharedStrings->new($self->{_archive});
}

sub styles {
    my ($self) = @_;
    $self->{_styles} ||= Data::XLSX::Parser::Styles->new($self->{_archive});
}

sub relationships {
    my ($self) = @_;
    $self->{_relationships} ||= Data::XLSX::Parser::Relationships->new($self->{_archive});
}

sub sheet {
    my ($self, $sheet_id) = @_;
    warn 'Data::XLSX::Parser->sheet is obsolete. This method will remove feature release.';
    $self->{_sheet}->{$sheet_id} ||= Data::XLSX::Parser::Sheet->new($self, $self->{_archive}, $sheet_id);
}

sub sheet_by_rid {
    my ($self, $rid) = @_;

    my $relation = $self->relationships->relation($rid);
    unless ($relation) {
        return;
    }

    if ($relation->{Type} eq $workbook_schema) {
        my $target = $relation->{Target};
        $self->{_sheet}->{$rid} ||=
            Data::XLSX::Parser::Sheet->new($self, $self->{_archive}, $target);
    }
}

sub _row_event {
    my ($self, $row) = @_;

    my $row_vals = [map { $_->{v} } @$row];
    for my $handler (@{ $self->{_row_event_handler} }) {
        $handler->($row_vals);
    }
}

1;

__END__