File Coverage

blib/lib/Data/UUID/Concise.pm

Criterion	Covered	Total	%
statement	57	57	100.0
branch			n/a
condition			n/a
subroutine	14	14	100.0
pod	2	2	100.0
total	73	73	100.0

use strictures 1;

package Data::UUID::Concise;

use 5.010;
use utf8;
use open qw(:std :utf8);
use charnames qw(:full :short);

use Moo;
use MooX::Types::MooseLike::Base qw(:all);

use Carp;
use Data::UUID;
use List::MoreUtils qw[ uniq ];
use Math::BigInt;

our $VERSION = '0.121240';    # VERSION

# ABSTRACT: Encode UUIDs to be more concise or communicable
# ENCODING: utf-8

has 'alphabet' => (
    is      => 'rw',
    isa     => Str,
    default => sub {
        '23456789ABCDEFGHJKLMNPQRSTUVWXYZabcdefghijkmnopqrstuvwxyz';
    },
);

around 'alphabet' => sub {
    my ( $next, $self, @rest ) = @_;
    return $self->$next unless @rest;

    my ( $alphabet_candidate ) = @rest;
    return $self->$next( _normalize_alphabet( $alphabet_candidate ) );
};

sub _normalize_alphabet
{
    my ( $alphabet_candidate ) = @_;

    my @symbols = split //, $alphabet_candidate;
    my @decruftified_symbols = uniq sort { $a cmp $b } @symbols;
    my $decruftified_alphabet = join '', @decruftified_symbols;

    return $decruftified_alphabet;
}

sub encode
{
    my ( $self, $uuid ) = @_;

    my $output = '';
    my $numeric =
        Math::BigInt->new( ( Data::UUID->new )->to_hexstring( $uuid ) );
    my $alphabet_length = length( $self->alphabet );

    while ( $numeric->is_positive ) {
        my $index = $numeric->copy->bmod( $alphabet_length );
        $output .= substr( $self->alphabet, $index, 1 );
        $numeric->bdiv( $alphabet_length );
    }

    return $output;
}

sub decode
{
    my ( $self, $string ) = @_;

    my $numeric         = Math::BigInt->new;
    my @characters      = split //, $string;
    my $alphabet_length = length( $self->alphabet );

    for my $character ( @characters ) {
        my $value = index $self->alphabet, $character;
        $numeric = $numeric->bmul( $alphabet_length );
        $numeric = $numeric->badd( $value );
    }

    return ( Data::UUID->new )->from_hexstring( $numeric->as_hex );
}

1;

__END__