File Coverage

blib/lib/Data/Turtle.pm

Criterion	Covered	Total	%
statement	65	65	100.0
branch			n/a
condition	3	6	50.0
subroutine	19	19	100.0
pod	12	12	100.0
total	99	102	97.0

package Data::Turtle;
our $AUTHORITY = 'cpan:GENE';

# ABSTRACT: Turtle Movement and State Operations

use Moo;
use Math::Trig qw(:pi);
use POSIX qw(ceil);

our $VERSION = '0.0207';

use constant K => pi / 180;


sub _init_x {
    my $self = shift;
    return $self->width / 2;
}

sub _init_y {
    my $self = shift;
    return $self->height / 2;
}

sub _init_heading {
    my $self = shift;
    return -90 % 360;
}


has width => (
    is => 'rw',
    default => sub { 500 },
);

has height => (
    is => 'rw',
    default => sub { 500 },
);


has x => (
    is => 'rw',
    lazy => 1,
    builder => \&_init_x,
);

has y => (
    is => 'rw',
    lazy => 1,
    builder => \&_init_y,
);

has heading => (
    is => 'rw',
    builder => \&_init_heading,
);


has pen_status => (
    is => 'rw',
    default => sub { 1 }, # Pen down
);

has pen_color => (
    is => 'rw',
    default => sub { 'black' },
);

has pen_size => (
    is => 'rw',
    default => sub { 1 },
);


sub home {
    my $self = shift;
    $self->x( $self->_init_x );
    $self->y( $self->_init_y );
    $self->heading( $self->_init_heading );
}


sub pen_up {
    my $self = shift;
    $self->pen_status(0);
}


sub pen_down {
    my $self = shift;
    $self->pen_status(1);
}


sub right {
    my $self = shift;
    my $degrees = shift // 0;
    $self->heading(($self->heading + $degrees) % 360);
}


sub left {
    my $self = shift;
    my $degrees = shift // 0;
    $self->heading(($self->heading - $degrees) % 360);
}


sub position {
    my $self = shift;
    return ceil($self->x), ceil($self->y);
}


sub get_state {
    my $self = shift;
    return
        ceil($self->x),
        ceil($self->y),
        $self->heading,
        $self->pen_status,
        $self->pen_color,
        $self->pen_size;
}


sub set_state {
    my $self = shift;
    my ($x, $y, $heading, $pen_status, $pen_color, $pen_size) = @_;
    $self->x($x);
    $self->y($y);
    $self->heading($heading);
    $self->pen_status($pen_status);
    $self->pen_color($pen_color);
    $self->pen_size($pen_size);
}


sub forward {
    my $self = shift;
    my $step = shift // 1;

    my $x = $step * cos($self->heading * K);
    my $y = $step * sin($self->heading * K);

    my $xo = $self->x;
    my $yo = $self->y;

    $self->x($x + $xo);
    $self->y($y + $yo);

    return ceil($xo), ceil($yo),
        ceil($self->x), ceil($self->y),
        $self->pen_color, $self->pen_size;
}


sub backward {
    my $self = shift;
    my $step = shift;
    $self->forward(-$step)
}


sub mirror {
    my $self = shift;
    $self->heading($self->heading * -1);
}


sub goto {
    my $self = shift;
    my ($x, $y) = @_;

    my $xo = $self->x;
    my $yo = $self->y;

    $self->x($x);
    $self->y($y);

    return ceil($xo), ceil($yo),
        ceil($self->x), ceil($self->y),
        $self->pen_color, $self->pen_size;
}

1;

__END__