File Coverage

blib/lib/Data/Sah/DefaultValueCommon.pm

Criterion	Covered	Total	%
statement	42	45	93.3
branch	10	12	83.3
condition	3	6	50.0
subroutine	3	3	100.0
pod	1	1	100.0
total	59	67	88.0

package Data::Sah::DefaultValueCommon;

use 5.010001;
use strict 'subs', 'vars';

our $AUTHORITY = 'cpan:PERLANCAR'; # AUTHORITY
our $DATE = '2024-01-17'; # DATE
our $DIST = 'Data-Sah-DefaultValue'; # DIST
our $VERSION = '0.005'; # VERSION

our %common_args = (
    default_value_rules => {
        summary => 'A specification of default-value rules to use (or avoid)',
        schema => ['array*', of=>'str*'],
        description => <<'_',

This setting is used to specify which default-value rules to use (or avoid) in a
flexible way. Each element is a string, in the form of either `NAME` to mean
specifically include a rule, or `!NAME` to exclude a rule.

To use the default-value rules R1 and R2:

    ['R1', 'R2']
_
    },
);

our %gen_default_value_code_args = (
    %common_args,
    source => {
        summary => 'If set to true, will return coercer source code string'.
            ' instead of compiled code',
        schema => 'bool',
    },
);

our %SPEC;

$SPEC{get_default_value_rules} = {
    v => 1.1,
    summary => 'Get default-value rules',
    description => <<'_',

This routine determines default-value rule modules to use (based on the
`default_value_rules` specified), loads them, filters out modules with
old/incompatible metadata version, and return the list of rules.

This common routine is used by  compilers, as well as
 and .

_
    args => {
        %common_args,
        compiler => {
            schema => 'str*',
            req => 1,
        },
        extra_args => {
            summary => 'Extra arguments to pass to value() subroutine',
            schema => 'hash*',
            description => <<'MARKDOWN',

This is used, for example, by  when generating validation code
from Sah schema. Sometimes the default value rule needs to know additional
information like what a date type should be coerced to (DateTime object, or
epoch) so it can generate the appropriate default value.

MARKDOWN
        },
    },
};
sub get_default_value_rules {
    my %args = @_;

    my $compiler = $args{compiler};

    my $prefix = "Data::Sah::Value::$compiler\::";

    my @rules0;
    for my $item (@{ $args{default_value_rules} // [] }) {
        my $rule_name = ref $item eq 'ARRAY' ? $item->[0] : $item;
        my $is_exclude = $rule_name =~ s/\A!//;
        if ($is_exclude) {
            @rules0 = grep { $_ ne $rule_name } @rules0;
        } else {
            push @rules0, $item unless grep { $_ eq $rule_name } @rules0;
        }
    }

    my @rules;
    for my $item (@rules0) {
        my ($rule_name, $rule_gen_args);
        if (ref $item eq 'ARRAY') {
            $rule_name = $item->[0];
            $rule_gen_args = $item->[1];
        } else {
            if ($item =~ /(.*?)=(.*)/) {
                $rule_name = $1;
                $rule_gen_args = {split /,/, $2};
            } else {
                $rule_name = $item;
                $rule_gen_args = undef;
            }
        }

        my $mod = $prefix . $rule_name;
        (my $mod_pm = "$mod.pm") =~ s!::!/!g;
        require $mod_pm;
        my $rule_meta = &{"$mod\::meta"};
        my $rule_v = ($rule_meta->{v} // 1);
        if ($rule_v != 1) {
            warn "Only value rule module following metadata version 1 is ".
                "supported, this rule module '$mod' follows metadata version ".
                "$rule_v and will not be used";
            next;
        }
        my $rule = &{"$mod\::value"}(
            (args => $rule_gen_args) x !!$rule_gen_args,
            %{ $args{extra_args} // {} },
        );
        $rule->{name} = $rule_name;
        $rule->{meta} = $rule_meta;
        push @rules, $rule;
    }

    \@rules;
}

1;
# ABSTRACT: Common stuffs for Data::Sah::DefaultValue and Data::Sah::DefaultValueJS

__END__