File Coverage

blib/lib/Data/Resolver/Alternatives.pm

Criterion	Covered	Total	%
statement	65	72	90.2
branch	2	4	50.0
condition	2	2	100.0
subroutine	16	18	88.8
pod	6	6	100.0
total	91	102	89.2

#!/usr/bin/env perl
package Data::Resolver::Alternatives;
use v5.24;
use warnings;

use Moo;
use experimental 'signatures';
use namespace::clean;

extends 'Data::Resolver::Base';

has alternatives => (is => 'ro', required => 1);

sub _uniq_map ($self, $cb) {
   my %seen;
   grep { !$seen{$_}++ } map { $cb->($_) } $self->alternatives->@*;
}

sub _first ($self, $test) {
   $test->($_) && return $_ for $self->alternatives->@*;
   return;
}

sub get_asset ($self, $key) {
   my $provider = $self->_first(sub { $_[0]->has_asset($key) })
     or $self->not_found($key);
   return $provider->get_asset($key);
}

sub get_sub_resolver ($self, $key) {
   my @subs =
      map  { $_->get_sub_resolver($key) }
      grep { $_->has_sub_resolver($key) }
      $self->alternatives->@*;
   $self->not_found($key) unless @subs;
   return ref($self)->new(alternatives => \@subs);
}

sub has_asset ($self, $key) {
   !!($self->_first(sub { $_[0]->has_asset($key) }));
}

sub has_sub_resolver ($self, $key) {
   !!($self->_first(sub { $_[0]->has_sub_resolver($key) }));
}

sub list_asset_keys ($self) {
   $self->_uniq_map(sub ($resolver) { $resolver->list_asset_keys });
}

sub list_sub_resolver_keys ($self) {
   $self->_uniq_map(sub ($resolver) { $resolver->list_sub_resolver_keys });
}

1;