File Coverage

blib/lib/Data/Record/Serialize/Encode/html.pm

Criterion	Covered	Total	%
statement	35	35	100.0
branch	7	14	50.0
condition	6	17	35.2
subroutine	11	11	100.0
pod	0	4	0.0
total	59	81	72.8

package Data::Record::Serialize::Encode::html;

# ABSTRACT: encode a record as html

use v5.10;

use Moo::Role;

our $VERSION = '0.02';

use warnings::register;

use namespace::clean;

has _html => (
    is       => 'lazy',
    init_arg => undef,
    builder  => sub {
        require HTML::Tiny;
        HTML::Tiny->new( mode => 'html' );
    },
);

has _closed => (
    is       => 'rwp',
    init_arg => undef,
    default  => 1,
);



























has [ 'table_class', 'thead_class', 'tbody_class', 'td_class', 'tr_class', 'th_class' ] => (
    is        => 'ro',
    predicate => 1,
);

has _class => (
    is        => 'lazy',
    init_args => undef,
    builder   => sub {
        my $self = shift;
        {
            table => $self->has_table_class ? { class => $self->table_class } : undef,
            thead => $self->has_thead_class ? { class => $self->thead_class } : undef,
            th    => $self->has_th_class    ? { class => $self->th_class }    : undef,
            td    => $self->has_td_class    ? { class => $self->td_class }    : undef,
            tr    => $self->has_tr_class    ? { class => $self->tr_class }    : undef,
        };
    },
);

sub _needs_eol { 0 }

sub encode {
    my $self = shift;
    $self->_html->tr( [
            $self->_html->td(
                $self->_class->{td} // (),
                map { $_ // q{} } @{ $_[0] }{ @{ $self->output_fields } } ) ] );
}

sub setup {
    my $self = shift;
    my $html = $self->_html;
    $self->say( $html->open( 'table', $self->_class->{table} // () ) );

    $self->say(
        $html->thead( [
                $html->tr(
                    $self->_class->{'tr'} // (),
                    [ $html->th( $self->_class->{th} // (), @{ $self->output_fields } ) ],
                ),
            ],
        ),
    );
    $self->say( $html->open( 'tbody', $self->_class->{tbody} // () ) );
    $self->_set__closed( 0 );
}

sub finalize {
    my $self = shift;
    return if $self->_closed;
    $self->say( $self->_html->close( 'tbody' ) );
    $self->say( $self->_html->close( 'table' ) );
    $self->_set__closed( 1 );
}


sub DEMOLISH {
    my $self = shift;

    warnings::warnif( 'Data::Record::Serialize::Encode::html',
        __PACKAGE__ . ': html table is not closed' )
      unless $self->_closed;
}

with 'Data::Record::Serialize::Role::Encode';

1;

#
# This file is part of Data-Record-Serialize-Encode-html
#
# This software is Copyright (c) 2024 by Smithsonian Astrophysical Observatory.
#
# This is free software, licensed under:
#
#   The GNU General Public License, Version 3, June 2007
#

__END__