File Coverage

blib/lib/Data/Localize/YAML.pm

Criterion	Covered	Total	%
statement	55	60	91.6
branch	6	10	60.0
condition	2	5	40.0
subroutine	13	14	92.8
pod	3	4	75.0
total	79	93	84.9

package Data::Localize::YAML;
$Data::Localize::YAML::VERSION = '0.002';
use v5.10;
use strict;
use warnings;

use Moo;
use File::Basename;
use Data::Localize;
use Data::Localize::Storage::Hash;
use YAML::PP qw(LoadFile);
use Carp qw(croak);

BEGIN {
	if (Data::Localize::DEBUG) {
		require Data::Localize::Log;
		Data::Localize::Log->import;
	}
}

extends 'Data::Localize::Localizer';
with 'Data::Localize::Trait::WithStorage';

has 'is_array' => (
	is => 'ro',
	default => sub { 1 },
);

has 'array_key_value' => (
	is => 'ro',
	default => sub { [qw(id str)] },
);

has paths => (
	is => 'ro',
);

around register => sub {
	my ($next, $self, $loc) = @_;
	$self->$next($loc);
	$loc->add_localizer_map('*', $self);
};

sub BUILD
{
	my $self = shift;
	my $paths = $self->paths;
	foreach my $path (@$paths) {
		$self->load_from_path($path);
	}
}

sub BUILDARGS
{
	my ($class, %args) = @_;

	my $path = delete $args{path};
	if ($path) {
		$args{paths} ||= [];
		push @{$args{paths}}, $path;
	}
	$class->SUPER::BUILDARGS(%args);
}

sub add_path
{
	my $self = shift;
	push @{$self->paths}, @_;
	$self->load_from_path($_) for @_;
}

sub load_from_path
{
	my ($self, $path) = @_;

	return unless $path;

	if (Data::Localize::DEBUG) {
		debugf("load_from_path - loading from glob(%s)", $path);
	}

	foreach my $x (glob($path)) {
		$self->load_from_file($x) if -f $x;
	}
}

sub load_from_file
{
	my ($self, $file) = @_;

	if (Data::Localize::DEBUG) {
		debugf("load_from_file - loading from file %s", $file);
	}

	my @lexicon = LoadFile($file);
	my %hash_lexicon;

	if ($self->is_array) {
		my ($keykey, $valuekey) = @{$self->array_key_value};
		foreach my $item (@lexicon) {
			if (!exists $item->{$keykey} || !exists $item->{$valuekey}) {
				croak
					"Array element from YAML file does not contain $keykey or $valuekey - forgot to set array_key_value?";
			}

			$hash_lexicon{$item->{$keykey}} = $item->{$valuekey};
		}
	}
	else {
		%hash_lexicon = %{$lexicon[0]};
	}

	my $lang = File::Basename::basename($file);
	$lang =~ s/\.ya?ml$//;

	if (Data::Localize::DEBUG) {
		debugf("load_from_file - registering %d keys", scalar keys %hash_lexicon);
	}

	$self->merge_lexicon($lang, \%hash_lexicon);
}

1;

__END__