File Coverage

blib/lib/Data/Cuid.pm

Criterion	Covered	Total	%
statement	39	39	100.0
branch	4	4	100.0
condition			n/a
subroutine	15	15	100.0
pod	2	2	100.0
total	60	60	100.0

package Data::Cuid;

use strict;
use warnings;

our @EXPORT_OK;

BEGIN {
    use Exporter 'import';
    @EXPORT_OK = qw(cuid slug);
}

use List::Util ();
use Sys::Hostname ();
use Time::HiRes ();

our $size = 4;
our $base = 36;
our $cmax = ($base)**($size);

our $VERSION = "0.06";

{
    my $c = 0;

    sub _safe_counter {
        $c = $c < $cmax ? $c : 0;
        $c++;
    }
}

# from Math::Base36, but without using Math::BigInt (since only
# timestamp is the largest int used here )
sub _encode_base36 {
    my ( $n, $max ) = ( @_, 1 );

    my @res;
    while ($n) {
        my $remainder = $n % 36;
        unshift @res, $remainder <= 9 ? $remainder : chr( 55 + $remainder );
        $n = int $n / 36;
    }

    # also return this as a string of exactly $max characters; note
    # that this means numbers above 36**$max - 1 will be truncated to
    # $max size and be incorrect, unless $max is increased
    unshift @res, '0' while @res < $max;
    join '' => @res[ @res - $max .. $#res ];
}

# taken from the NodeJS version of fingerprint
# https://github.com/ericelliott/cuid/blob/master/lib/fingerprint.js
sub _fingerprint {
    my $padding = 2;
    my $pid = _encode_base36 $$, $padding;

    my $hostname = Sys::Hostname::hostname;
    my $id = List::Util::reduce { $a + ord($b) } length($hostname) + $base,
        split // => $hostname;

    join '' => $pid, _encode_base36 $id, $padding;
}

sub _random_block { _encode_base36 $cmax * rand() << 0, $size }

sub _timestamp {
    _encode_base36 sprintf( '%.0f' => Time::HiRes::time * 1000 ), 8;
}

sub cuid {
    lc join '' => 'c',
        _timestamp,
        _encode_base36( _safe_counter, $size ),
        _fingerprint,
        _random_block, _random_block;
}

sub slug {
    lc join '' => substr( _timestamp, -2 ),
        substr( _encode_base36(_safe_counter), -4 ),
        substr( _fingerprint, 0, 1 ), substr( _fingerprint, -1 ),
        substr( _random_block, -2 );
}

1;
__END__