File Coverage

blib/lib/Dancer2/Plugin/Menu.pm

Criterion	Covered	Total	%
statement	75	75	100.0
branch	14	16	87.5
condition	2	6	33.3
subroutine	13	13	100.0
pod	1	2	50.0
total	105	112	93.7

package Dancer2::Plugin::Menu ;
$Dancer2::Plugin::Menu::VERSION = '0.007';
use 5.010; use strict; use warnings;

# ABSTRACT: Automatically generate an HTML menu for your Dancer2 app

use Storable     'dclone';
use List::Util   'first';
use Data::Dumper 'Dumper';
use HTML::Element;
use Dancer2::Plugin;
use Dancer2::Core::Hook;

plugin_keywords qw ( menu_item );

# tree has nodes generated by menu_item function; used to generate menu items
has 'tree'       => ( is => 'rw', default => sub { { '/' => { children => {} } } } );

# sets up before_template hook to generate HTML from a modified copy of the tree
#TODO: fetch html from cache for paths already visited
sub BUILD {
  my $s = shift;

  $s->app->add_hook (Dancer2::Core::Hook->new (
    name => 'before_template',
    code => sub {

      # set active menu items on a copy of the tree
      my $new_tree = dclone $s->tree->{'/'};
      my $tree     = $new_tree;
      my $tokens   = shift;
      my @nodes = split /\//, $tokens->{request}->route->spec_route;
      foreach my $node (@nodes[1 .. @nodes-1]) {
        $tree->{children}{$node}{active} = 1;
        $tree = $tree->{children}{$node};
      }

      # generate html and send to template
      my $html = _get_html($new_tree, HTML::Element->new('ul'));
      $tokens->{menu} = $html->as_HTML('', "\t", {});
    }
  ));
}

# Builds tree and associates menu item data with each node in the tree. Called
# once for each route wrapped in the "menu_item" keyword.
sub menu_item {
  my $s        = shift;
  my $mi_data  = shift; # menu item data
  my $route    = shift;
  my $tree     = $s->tree;
  my @nodes    = split /\//, $route->spec_route;
  $nodes[0]    = '/'; # replace blank node with root node

  # add node for each segment of the path and associate data with it
  while (my $node = shift @nodes) {
    # populate the menu variables
    my $title            = ucfirst($node);
    my $weight           = 5;
    $mi_data->{title}  //= $title;
    $mi_data->{weight} //= $weight;

    # more nodes after this one so extend tree if next node doesn't already exist
    if (@nodes) {
      if (!$tree->{$node}{children}) {
        $tree->{$node}{children} = {};
      }
    # add mi_data if we are at the end of a path and therefore route
    } elsif (!$tree->{$node}{children}) {
      $tree->{$node} = $mi_data;
      $tree->{$node}{protected} = 1;  # don't let new routes clobber node
      next; # we can bail early on iteration and save 2 zillionths of a second
    }

    # add data to a node that is not at end of existing path
    if (!$tree->{$node}{protected}) {
      # if at node at end of route, add mi_data; otherwise defaults are used
      if (!@nodes) {
        ($title, $weight)            = ($mi_data->{title}, $mi_data->{weight});
        $tree->{$node}{protected} = 1;
      }
      $tree->{$node}{title}       = $title;
      $tree->{$node}{weight}      = $weight;
    }
    $tree = $tree->{$node}{children};
  }
}

# generate HTML menu from tree
sub _get_html {
  my ($tree, $element) = @_;

  # sort sibling menu items by weight and then by name
  foreach my $child (
    sort { ( $tree->{children}{$a}{weight} <=> $tree->{children}{$b}{weight} )
      ||   ( $tree->{children}{$a}{title}  cmp $tree->{children}{$b}{title}  )
         } keys %{$tree->{children}} ) {

    # create menu item list element with classes for css styling
    my $li_this = HTML::Element->new('li');
    $li_this->attr(class => $tree->{children}{$child}{active} ? 'active' : '');

    # add HTML elements for each menu item; recurse if menu item has children
    $li_this->push_content($tree->{children}{$child}{title});
    if ($tree->{children}{$child}{children}) {
      my $ul = HTML::Element->new('ul');
      $li_this->push_content($ul);
      $element->push_content($li_this);
      _get_html($tree->{children}{$child}, $ul)
    } else {
      $element->push_content($li_this);
    }
  }
  return $element;
}

1; # Magic true value

__END__