File Coverage

blib/lib/Dancer2/Plugin/Locale.pm

Criterion	Covered	Total	%
statement	21	21	100.0
branch			n/a
condition			n/a
subroutine	7	7	100.0
pod			n/a
total	28	28	100.0

package Dancer2::Plugin::Locale;

use strict;
use warnings;

use Dancer2::Plugin;
$Dancer2::Plugin::Locale::VERSION = '0.05';

package Dancer2::Plugin::Locale::Obj;
use Locales 0.33 unicode => 1;
use Locale::Maketext::Utils;
use base 'Locale::Maketext::Utils';
our %Lexicon;

package Dancer2::Plugin::Locale;

use File::Spec;

# use Tie::Hash::ReadonlyStack;

plugin_keywords 'locale';

sub locale {
    my $dsl = shift;

    if (@_) {
        return Dancer2::Plugin::Locale::Obj->get_handle( grep( { defined } (@_) ), 'en' );    # multiton already via Locale::Maketext::Utils
    }

    my $app  = $dsl->app;

    # TODO 2: request locale via browser/HTP req after session and before default?
    return Dancer2::Plugin::Locale::Obj->get_handle( grep( { defined } ( eval { $app->session->read('locale') }, $dsl->config->{default_locale} ) ), 'en' );    # multiton already via Locale::Maketext::Utils
};

sub BUILD {
    my $dsl = shift;

    my @available_locales = ('en');

    # read locale/ dir for available locales (via config also? likley YAGNI/overly comlicated-why?)
    my $locale_dir = File::Spec->catdir( $dsl->app->config->{'appdir'}, 'locale' );                                                                      # configurable? nah, why?
    if ( -d $locale_dir ) {
        if ( opendir my $dh, $locale_dir ) {
            while ( my $file = readdir($dh) ) {
                next if $file !~ m/\.json$/;
                next if $file eq 'en.json';
                $file =~ s/\.json//;
                if ( Locales::normalize_tag($file) ne $file ) {
                    warn "Skipping un-normalized locale named lexicon ($file.json) …\n";                                                               # just no apparent need to complicate things by trying to deal with this
                    next;
                }
                push @available_locales, $file;
            }
            closedir($dh);
        }
        else {
            die "Could not read locale directory ($locale_dir): $!\n";
        }
    }
    no strict 'refs';                                                                                                                                    ## no critic
    no warnings 'redefine';                                                                                                                              ## no critic
    *Locale::Maketext::Utils::list_available_locales = sub {
        return ( sort @available_locales );
    };

    # create classes that Locale::Maketext uses
    for my $tag (@available_locales) {
        my $file = File::Spec->catfile( $locale_dir, "$tag.json" );

        # TODO 1: for en (and its alias) empty value means key *is* value …

        # TODO 1: support tieing to CDB_File hash (e.g. if -f locale_cdb/$tag.cdb) so as not to load all the data into memory (see use_external_lex_cache)?

        # TODO 2: POD app w/ charset !utf8 == ick
        eval "package Dancer2::Plugin::Locale::Obj::$tag;use base 'Dancer2::Plugin::Locale::Obj';our \$Encoding='utf8';our \%Lexicon;package Dancer2::Plugin::Locale;";    ## no critic

        no strict 'refs';                                                                                                                                                  ## no critic
        %{"Dancer2::Plugin::Locale::Obj::$tag\::Lexicon"} = $tag eq 'en' && !-e $file ? () : ( %{ _from_json_file($file) } );                                              # TODO 1: instead: tie %{"Dancer2::Plugin::Locale::$tag\::Lexicon"}, 'Tie::Hash::ReadonlyStack', _from_json_file($file);
    }

    # TODO 2: Is there a better way to add template keyword?
    $dsl->app->add_hook(
        Dancer2::Core::Hook->new(
            name => 'before_template_render',
            code => sub {
                $_[0]->{locale} = sub { $dsl->locale(@_) };
            },
        )
    );
};

sub _from_json_file {
    my ($file) = @_;
    open( my $fh, '<', $file ) or die "Could not read “$file”: $!";
    return from_json(
        do { local $/; <$fh> }
    );
}

# TODO 2: localization tips
# TODO 2: extractor/checker tool

1;

__END__