File Coverage

blib/lib/Dancer2/Logger/Radis.pm

Criterion	Covered	Total	%
statement	33	33	100.0
branch	3	4	75.0
condition			n/a
subroutine	13	13	100.0
pod	0	5	0.0
total	49	55	89.0

use strictures 2;

package Dancer2::Logger::Radis;

# ABSTRACT: Dancer2 logger engine for Log::Radis

use Moo 2;
use Log::Radis 0.002;
use Carp qw(croak);
use FindBin qw($RealBin $RealScript);

my $BIN = "$RealBin/$RealScript";

with 'Dancer2::Core::Role::Logger';


our $VERSION = '0.002'; # VERSION


has server => (
    is => 'ro',
    default => 'localhost:6379',
);


has reconnect => (
    is => 'ro',
    default => 5,
);


has every => (
    is => 'ro',
    default => 1,
);


has queue => (
    is => 'ro',
    default => 'graylog-radis:queue',
);


has __mock => (
    is => 'ro',
);

has _radis => (
    is => 'lazy',
    builder => sub
    {
        my $self = shift;
        my %opts = (
            server      => $self->server,
            reconnect   => $self->reconnect,
            every       => $self->every,
            queue       => $self->queue,
        );
        if ($self->__mock) {
            $opts{redis} = $self->__mock;
        }
        Log::Radis->new(%opts);
    }
);

sub _dump
{
    Data::Dumper->new(\@_)->Terse(1)->Purity(1)->Indent(0)->Sortkeys(1)->Dump()
}

sub _serialize
{
    map { ref $_ ? _dump($_) : $_ } @_
}


sub log
{
    my $self = shift;
    my ($level, @args) = @_;
    my ($message, %extras) = map { _serialize($_) } @args;


    my %gelf = (
        _source     => $self->app_name,
        _pid        => $$,
        _bin        => $BIN,
        map {( '_dancer_'.lc($_) => $extras{$_} )} keys %extras
    );

    if (my $request = $self->request) {
        $gelf{_http_id}         = $request->id;
        $gelf{_http_user}       = $request->user;
        $gelf{_http_client}     = $request->address;
        $gelf{_http_method}     = $request->method;
        $gelf{_http_path}       = $request->path;
        $gelf{_http_proto}      = $request->protocol;
        $gelf{_http_referer}    = $request->header('referer');
        $gelf{_http_useragent}  = $request->header('user_agent');
        if ($self->has_session) {
            $gelf{_session_id} = $request->session->id;
        }
    }

    $self->_radis->log($level, $message, %gelf);
}


sub core    { @_ = (shift, 'core',    @_); goto &log }
sub debug   { @_ = (shift, 'debug',   @_); goto &log }
sub info    { @_ = (shift, 'info',    @_); goto &log }
sub warning { @_ = (shift, 'warning', @_); goto &log }
sub error   { @_ = (shift, 'error',   @_); goto &log }

1;

__END__