File Coverage

blib/lib/Dancer2/Logger/Radis.pm

Criterion	Covered	Total	%
statement	23	34	67.6
branch	2	6	33.3
condition			n/a
subroutine	6	6	100.0
pod	1	1	100.0
total	32	47	68.0

use strictures 2;

package Dancer2::Logger::Radis;

# ABSTRACT: Dancer2 logger engine for Log::Radis

use Moo 2;
use Log::Radis 0.002;
use Devel::StackTrace;

with 'Dancer2::Core::Role::Logger';


our $VERSION = '0.001'; # VERSION


has server => (
    is => 'ro',
    default => 'localhost:6379',
);


has reconnect => (
    is => 'ro',
    default => 5,
);


has every => (
    is => 'ro',
    default => 1,
);


has queue => (
    is => 'ro',
    default => 'graylog-radis:queue',
);


has __mock => (
    is => 'ro',
);

has _radis => (
    is => 'lazy',
    builder => sub {
        my $self = shift;
        my %opts = (
            server => $self->server,
            reconnect => $self->reconnect,
            every => $self->every,
            queue => $self->queue,
        );
        if ($self->__mock) {
            $opts{redis} = $self->__mock;
        } else {
            die('meh');
        }
        Log::Radis->new(%opts);
    }
);


sub log {
    my $self = shift;
    my ($level, $message) = @_;
    my $caller = Devel::StackTrace->new->frame(5);


    my %hash = (
        _source => $self->app_name,
        _pid => $$,
        _package => $caller->package,
        _filename => $caller->filename,
        _line => $caller->line,
    );
    if (my $request = $self->request) {
        $hash{_http_id} = $request->id;
        $hash{_http_user} = $request->user;
        $hash{_http_client} = $request->address;
        $hash{_http_method} = $request->method;
        $hash{_http_path} = $request->path;
        $hash{_http_proto} = $request->protocol;
        $hash{_http_referer} = $request->header('referer');
        $hash{_http_useragent} = $request->header('user_agent');
        if ($self->_has_session) {
            $hash{_session_id} = $request->session->id;
        }
    }
    $self->_radis->log($level, $message, %hash);
}

1;

__END__