File Coverage

blib/lib/Dancer2/FileUtils.pm

Criterion	Covered	Total	%
statement	35	39	89.7
branch	9	10	90.0
condition			n/a
subroutine	12	13	92.3
pod	8	8	100.0
total	64	70	91.4

package Dancer2::FileUtils;
# ABSTRACT: File utility helpers
$Dancer2::FileUtils::VERSION = '2.1.0';
use strict;
use warnings;

use Path::Tiny ();
use Carp;

use Exporter 'import';
our @EXPORT_OK = qw(
  dirname open_file path read_file_content read_glob_content
  path_or_empty set_file_mode escape_filename
);


sub path {
    my @parts = @_;
    return Path::Tiny::path(@parts)->stringify;
}

sub path_or_empty {
    my @parts = @_;
    my $path  = Path::Tiny::path(@parts);

    # return empty if it doesn't exist
    return $path->exists ? $path->stringify : '';
}

sub dirname { return Path::Tiny::path(@_)->parent->stringify; }

sub set_file_mode {
    my $fh      = shift;
    my $charset = 'UTF-8';
    binmode $fh, ":encoding($charset)";
    return $fh;
}

sub open_file {
    my ( $mode, $filename, $charset ) = @_;

    return Path::Tiny::path($filename)->filehandle(
        $mode, ':encoding(UTF-8)',
    );
}

sub read_file_content {
    my ( $file, $charset ) = @_;
    $file or return;
    my $fh = open_file( '<', $file, $charset );

    return wantarray
      ? read_glob_content($fh)
      : scalar read_glob_content($fh);
}

sub read_glob_content {
    my $fh = shift;

    my @content = <$fh>;
    close $fh;

    return wantarray ? @content : join '', @content;
}

sub escape_filename {
    my $filename = shift or return;

    # based on escaping used in CHI::Driver. Our use-case is one-way,
    # so we allow utf8 chars to be escaped, but NEVER do the inverse
    # operation.
    $filename =~ s/([^A-Za-z0-9_\=\-\~])/sprintf("+%02x", ord($1))/ge;
    return $filename;
}

1;

__END__